Calculate length of path between nodes?

by

This is based on the same technique used to compute the position of an element in an RDF list using SPARQL that is described in: Is it possible to get the position of an element in an RDF Collection in SPARQL?

If you have data like this: 

@prefix : <http://example.org> .

:orgA :hasSuborganization :orgB, :orgC, :orgD.
:orgB :hasSuborganization :orgE, :orgF.
:orgE :hasSuborganization :orgG.
:orgG :hasSuborganization :orgH.

which describes a hierarchy like this:

organization hierarchy

then you can use a query like this:

prefix : <http://example.org> 

select ?super ?sub (count(?mid) as ?distance) { 
  ?super :hasSuborganization* ?mid .
  ?mid :hasSuborganization+ ?sub .
}
group by ?super ?sub 
order by ?super ?sub

to get results like these:

$ sparql --query query.rq --data subs.n3
----------------------------
| super | sub   | distance |
============================
| :orgA | :orgB | 1        |
| :orgA | :orgC | 1        |
| :orgA | :orgD | 1        |
| :orgA | :orgE | 2        |
| :orgA | :orgF | 2        |
| :orgA | :orgG | 3        |
| :orgA | :orgH | 4        |
| :orgB | :orgE | 1        |
| :orgB | :orgF | 1        |
| :orgB | :orgG | 2        |
| :orgB | :orgH | 3        |
| :orgE | :orgG | 1        |
| :orgE | :orgH | 2        |
| :orgG | :orgH | 1        |
----------------------------

The trick here is to recognize that any path from X to Y can be viewed as a (possibly empty) path from X to some intermediate node Z (nonempty means that you can choose X as Z) concatenated with a (non empty) path from Z to Y. The number of possible ways of picking Z indicates the length of the path.

More Related Contents:

  1. Is it possible to get the position of an element in an RDF Collection in SPARQL?
  2. Finding all steps in property path
  3. DBpedia Jena Query returning null
  4. Querying Open Data Communities Data with SPARQL
  5. Exploratory SPARQL queries?
  6. Sparql query Subclass or EquivalentTo
  7. SPARQL functions in CONSTRUCT/WHERE
  8. SPARQL property path queries with arbitrary properties
  9. get latitude and longitude of a place dbpedia
  10. How to infer isBrotherOf property between two individuals
  11. Aggregating results from SPARQL query
  12. How can I express additional information (time, probability) about a relation in RDF?
  13. How to access OWL documents using XPath in Java?
  14. How to convert RDF to pretty nested JSON using java rdf4j
  15. SPARQL: is there any path between two nodes?
  16. Exclude results from DBpedia SPARQL query based on URI prefix
  17. Why is dbpedia-owl:wikiPageRedirects not returning the full set of redirect links? (Sparql)
  18. What is a good RDF library for .net? [closed]
  19. Why does my SPARQL query return the URI of a resource instead of its name?
  20. wikidata get all properties with labels and values of an item
  21. Some cities aren’t instances of city or big city? Odd behaviour of Wikidata
  22. How to get only the most recent value from a Wikidata property?
  23. SPARQL query to get all class label with namespace prefix defined
  24. How to get all companies from DBPedia?
  25. SPARQL query to get all parent of a node
  26. edit uri of existing resource using jena

Leave a Comment