Calling WCF service by VBScript

by

Don’t use MSSOAP. I think it is out of support now, for the past 3 or 4 years. Consider using the XmlHttp, which is part of MSXML, and is supported and continues to be maintained. You will have to construct a SOAP envelope manually. But it’s more reliable this way.

example code

' URL to the WCF service'
url= "http://server:port/Wcf.Service.Address"

Dim requestDoc
Set requestDoc = WScript.CreateObject("MSXML2.DOMDocument.6.0")

Dim root
Set root = requestDoc.createNode(1, "Envelope", "http://schemas.xmlsoap.org/soap/envelope/")
requestDoc.appendChild root

Dim nodeBody
Set nodeBody = requestDoc.createNode(1, "Body", "http://schemas.xmlsoap.org/soap/envelope/")
root.appendChild nodeBody

Dim nodeOp
Set nodeOp = requestDoc.createNode(1, "Register", "urn:Your.Namespace.Here")
nodeBody.appendChild nodeOp

Dim nodeRequest
Set nodeRequest = requestDoc.createNode(1, "request", "urn:Your.Namespace.Here")
'content of the request will vary depending on the WCF Service.'
' This one takes just a plain string. '
nodeRequest.text = "Hello from a VBScript client."

nodeOp.appendChild nodeRequest

Set nodeRequest = Nothing
Set nodeOp = Nothing
Set nodeBody = Nothing
Set root = Nothing


'the request will look like this:'
'       <s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/"> '
'         <s:Body> '
'           <Register xmlns="urn:Your.Namespace.Here"> '
'               <request>hello from a VBScript client.</request> '
'           </Register> '
'         </s:Body> '
'       </s:Envelope>'


WSCript.Echo  "sending request " & vbcrlf & requestDoc.xml


dim xmlhttp

set xmlhttp = WScript.CreateObject("MSXML2.ServerXMLHTTP.6.0")
' set the proxy as necessary and desired '
xmlhttp.setProxy 2, "http://localhost:8888"
xmlhttp.Open "POST", url, False
xmlhttp.setRequestHeader "Content-Type", "text/xml"
' set SOAPAction as appropriate for the operation '
xmlhttp.setRequestHeader "SOAPAction", "urn:Set.As.Appropriate"
xmlhttp.send requestDoc.xml

WScript.Echo vbcrlf & "Raw XML response:" & vbcrlf 
WSCript.Echo  xmlhttp.responseXML.xml

dim response
set response= xmlhttp.responseXML
'the response is an MSXML2.DOMDocument.6.0' 
'party on the response here - XPath, walk the DOM, etc. '

FYI: See which-version-of-msxml-should-i-use to learn how to select a version of MSXML.

More Related Contents:

  1. How to turn on WCF tracing?
  2. Best Practices for securing a REST API / web service [closed]
  3. WCF Configuration without a config file
  4. Returning raw json (string) in wcf
  5. WCF Datacontract, some fields do not deserialize
  6. HTTP could not register URL http://+:8000/HelloWCF/. Your process does not have access rights to this namespace
  7. WCFTestClient The HTTP request is unauthorized with client authentication scheme ‘Anonymous’
  8. The maximum string content length quota (8192) has been exceeded while reading XML data
  9. What is the difference between a WCF Service Application and a WCF Service Library?
  10. HTTP Error 404.3 – Not Found” while browsing wcf service on Windows Server 2008(64bit)
  11. How to get working path of a wcf application?
  12. WCF Service , how to increase the timeout?
  13. How to remove the “.svc” extension in RESTful WCF service?
  14. Increasing the timeout value in a WCF service
  15. Web Service vs WCF Service
  16. WCF service configuration file question regarding
  17. How to consume WCF web service through URL at run time?
  18. Invoking WCF service method through a browser
  19. WSDL-first approach: How to specify different names for wsdl:port and wsdl:binding?
  20. Connecting via named pipe from windows service (session#0) to desktop app (session #1)
  21. WCF: Configuring Known Types
  22. Traversing all nodes in an XML file with VBScript
  23. access HttpContext.Current from WCF Web Service
  24. How do I tell WCF to skip verification of the certificate?
  25. WCF GZip Compression Request/Response Processing
  26. How can I use WCF with the basichttpbinding only , SSL and Basic Authentication in IIS?
  27. WCF Web Service Custom Exception Error to Client
  28. Expose a WCF Service through a Named Pipes binding
  29. Hosting WCF service inside a Windows Forms application
  30. How to handle json DateTime returned from WCF Data Services (OData)

Leave a Comment