Finding the difference between two dateTimes in XSLT

by

I am getting the error: … xsl:version: only 1.0 features are supported

Here’s a purely XSLT 1.0 solution:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="event">
    <xsl:variable name="start">
        <xsl:call-template name="dateTime-to-seconds">
            <xsl:with-param name="dateTime" select="start/@time" />
        </xsl:call-template>
    </xsl:variable> 
    
    <xsl:variable name="end">
        <xsl:call-template name="dateTime-to-seconds">
            <xsl:with-param name="dateTime" select="end/@time" />
        </xsl:call-template>
    </xsl:variable>
    
    <xsl:variable name="duration" select="$end - $start" />
    <xsl:variable name="d" select="floor($duration div 86400)"/>
    <xsl:variable name="t" select="$duration mod 86400"/>
    <xsl:variable name="h" select="floor($t div 3600)"/>
    <xsl:variable name="r" select="$t mod 3600"/>
    <xsl:variable name="m" select="floor($r div 60)"/>
    <xsl:variable name="s" select="$r mod 60"/>
    
    <xsl:copy>
        <xsl:copy-of select="name"/>
        <duration>
            <xsl:value-of select="$d"/>
            <xsl:text> days, </xsl:text>
            <xsl:value-of select="$h"/>
            <xsl:text> hours, </xsl:text>
            <xsl:value-of select="$m"/>
            <xsl:text> minutes and </xsl:text>
            <xsl:value-of select="$s"/>
            <xsl:text> seconds</xsl:text>
        </duration>
    </xsl:copy>
</xsl:template>

<xsl:template name="dateTime-to-seconds">
    <xsl:param name="dateTime"/>

    <xsl:variable name="date" select="substring-before($dateTime, 'T')" />
    <xsl:variable name="time" select="substring-after($dateTime, 'T')" />

    <xsl:variable name="local-time" select="substring($time, 1, string-length($time) - 6)" />
    <xsl:variable name="offset" select="substring-after($time, $local-time)" />

    <xsl:variable name="year" select="substring($date, 1, 4)" />
    <xsl:variable name="month" select="substring($date, 6, 2)" />
    <xsl:variable name="day" select="substring($date, 9, 2)" />

    <xsl:variable name="hour" select="substring($local-time, 1, 2)" />
    <xsl:variable name="minute" select="substring($local-time, 4, 2)" />
    <xsl:variable name="second" select="substring($local-time, 7)" />

    <xsl:variable name="offset-sign" select="1 - 2 * starts-with($offset, '-')" />
    <xsl:variable name="offset-hour" select="substring($offset, 2, 2) * $offset-sign" />
    <xsl:variable name="offset-minute" select="substring($offset, 5, 2) * $offset-sign" />

    <xsl:variable name="a" select="floor((14 - $month) div 12)"/>
    <xsl:variable name="y" select="$year + 4800 - $a"/>
    <xsl:variable name="m" select="$month + 12*$a - 3"/>    
    <xsl:variable name="jd" select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />

    <xsl:value-of select="86400*$jd + 3600*$hour + 60*$minute + $second - 3600*$offset-hour - 60*$offset-minute" />
</xsl:template> 

</xsl:stylesheet>

Demo: http://xsltfiddle.liberty-development.net/aiyndK

More Related Contents:

  1. How to remove elements from xml using xslt with stylesheet and xsltproc?
  2. xsl: how to split strings?
  3. XSL xsl:template match=”/”
  4. Current node vs. Context node in XSLT/XPath?
  5. XPath select all elements between two specific elements
  6. XSLT: How to convert XML Node to String
  7. How to iterate over IDREFS values in XSLT 1.0?
  8. XPath with multiple conditions
  9. Is there an XSLT name-of element?
  10. How do you output the current element path in XSLT?
  11. XSLT Replace function not found
  12. What is the difference between ‘or’ and ‘|’ when programming in xslt?
  13. For loops vs. apply-templates
  14. Concatenate multiple node values in xpath
  15. What browsers support XSLT 2.0?
  16. Preserving entity references when transforming XML with XSLT?
  17. WiX Installer: using xslt with heat.exe to update attributes
  18. How do I generate a comma-separated list with XSLT/XPath?
  19. XSLT – How to keep only wanted elements from XML
  20. How to read plain text content with XSLT 1.0
  21. XSLT – Comparing preceding-sibling’s elements with current’s node element
  22. XPath query to get nth instance of an element
  23. Case insensitive XPath contains() possible?
  24. Can Chrome be made to perform an XSL transform on a local file?
  25. Xml Namespace breaking my xpath!
  26. XSLT: How to change an attribute value during ?
  27. Using XPath, How do I select a node based on its text content and value of an attribute?
  28. distinct in Xpath?
  29. How can I select an element with multiple classes with Xpath?
  30. XSLT Transformation – dynamic element names

Leave a Comment