How to run batch script without using *.bat extension

by

This is an interesting topic to me! I want to do some observations about it.

The important point first: A Batch file is a file with .BAT or .CMD extension. Period. Batch files can achieve, besides the execution of usual DOS commands, certain specific Batch-file facilities, in particular:

  • Access to Batch file parameters via %1 %2 … and execution of SHIFT command.
  • Execution of GOTO command.
  • Execution of CALL :NAME command (internal subroutine).
  • Execution of SETLOCAL/ENDLOCAL commands.

Now the funny part: Any file can be redirected as input for CMD.exe so the DOS commands contained in it are executed in a similar way of a Batch file, with some differences. The most important one is that previous Batch-file facilities will NOT work. Another differences are illustrated in the NOT-Batch file below (I called it BATCH.TXT):

@echo off
rem Echo off just suppress echoing of the prompt and each loop of FOR command
rem but it does NOT suppress the listing of these commands!

rem Pause command does NOT pause, because it takes the character that follows it
pause
X

rem This behavior allows to put data for a SET /P command after it
set /P var=Enter data: 
This is the data for previous command!
echo Data read: "%var%"

rem Complex FOR/IF commands may be assembled and they execute in the usual way:
for /L %i in (1,1,5) do (
   set /P line=
   if "!line:~0,6!" equ "SHOW: " echo Line read: !line:~6!
)
NOSHOW: First line read
SHOW: Second line
NOSHOW: This is third line
SHOW: The line number 4
NOSHOW: Final line, number five

rem You may suppress the tracing of the execution redirecting CMD output to NUL
rem In this case, redirect output to STDERR to display messages in the screen
echo This is a message redirected to STDERR >&2

rem GOTO command doesn't work:
goto label
goto :EOF
rem but both EXIT and EXIT /B commands works:
exit /B

:label
echo Never reach this point...

To execute previous file, type: CMD /V:ON < BATCH.TXT
The /V switch is needed to enable delayed expansion.

More specialized differences are related to the fact that commands in the NOT-Batch file are executed in the command-line context, NOT the Batch-file context. Perhaps Dave or jeb could elaborate on this point.

EDIT: Additional observations (batch2.txt):

@echo off
rem You may force SET /P command to read the line from keyboard instead of
rem from following lines by redirecting its input to CON device.

rem You may also use CON device to force commands output to console (screen),
rem this is easier to write and read than >&2

echo Standard input/output operations> CON
echo/> CON
< CON set /P var=Enter value: > CON
echo/> CON
echo The value read is: "%var%"> CON

Execute previous file this way: CMD < BATCH2.TXT > NUL

EDIT: More additional observations (batch3.txt)

@echo off

rem Dynamic access to variables that usually requires DelayedExpansion via "call" trick

rem Read the next four lines; "next" means placed after the FOR command
rem (this may be used to simulate a Unix "here doc")

for /L %i in (1,1,4) do (
   set /P line[%i]=
)
Line one of immediate data
This is second line
The third one
And the fourth and last one...

(
echo Show the elements of the array read:
echo/
for /L %i in (1,1,4) do call echo Line %i- %line[%i]%
) > CON

Execute this file in the usual way: CMD < BATCH3.TXT > NUL

Interesting! Isn’t it?

EDIT: Now, GOTO and CALL commands may be simulated in the NotBatch.txt file!!! See this post.

Antonio

More Related Contents:

  1. edit 2500 text files to add three decimal places for integer number and decimal number where you can find after @x*
  2. What are the undocumented features and limitations of the Windows FINDSTR command?
  3. JDBC batch insert performance
  4. Wait for shell command to complete [duplicate]
  5. Error: “is not recognized as an internal or external command, operable program or batch file”
  6. Where is “START” searching for executables?
  7. heredoc for Windows batch?
  8. What does %~d0 mean in a Windows batch file?
  9. How to run a PowerShell script from a batch file
  10. How to read file contents into a variable in a batch file?
  11. How can a .bat file be ‘converted’ to .exe without third party tools?
  12. Run batch file as a Windows service
  13. How to create empty text file from a batch file?
  14. Gradle to execute Java class (without modifying build.gradle)
  15. What does symbol ^ mean in Batch script?
  16. How to Copy (and increment) Multiple Instances of a File Using Batch File
  17. How to add a set path only for that batch file executing?
  18. Split string with string as delimiter
  19. How to change Screen buffer size in Windows Command Prompt from batch script
  20. Delete all files and folders in a directory
  21. Script to change ip address on windows
  22. Get java version from batch file
  23. How to capture cURL output to a file?
  24. Best way to script remote SSH commands in Batch (Windows)
  25. Batch program to to check if process exists
  26. How does “FOR” work in cmd batch file?
  27. Foolproof way to check for nonzero (error) return code in windows batch file
  28. Windows batch script to delete everything in a folder except one
  29. ERRORLEVEL vs %ERRORLEVEL% vs exclamation mark ERRORLEVEL exclamation mark
  30. Create a list or an array and print each item in Windows Batch

Leave a Comment