Multiple choices menu on batch file?

by

Answer

This will do what you want. Let me know if you have any questions. All you have to do is follow the two steps listed in the script.

Script

:: Hide Command and Set Scope
@echo off
setlocal EnableExtensions

:: Customize Window
title My Menu

:: Menu Options
:: Specify as many as you want, but they must be sequential from 1 with no gaps
:: Step 1. List the Application Names
set "App[1]=One"
set "App[2]=Two"
set "App[3]=Three"
set "App[4]=Four"
set "App[5]=Five"
set "App[6]=All Apps"

:: Display the Menu
set "Message="
:Menu
cls
echo.%Message%
echo.
echo.  Menu Title
echo.
set "x=0"
:MenuLoop
set /a "x+=1"
if defined App[%x%] (
    call echo   %x%. %%App[%x%]%%
    goto MenuLoop
)
echo.

:: Prompt User for Choice
:Prompt
set "Input="
set /p "Input=Select what app:"

:: Validate Input [Remove Special Characters]
if not defined Input goto Prompt
set "Input=%Input:"=%"
set "Input=%Input:^=%"
set "Input=%Input:<=%"
set "Input=%Input:>=%"
set "Input=%Input:&=%"
set "Input=%Input:|=%"
set "Input=%Input:(=%"
set "Input=%Input:)=%"
:: Equals are not allowed in variable names
set "Input=%Input:^==%"
call :Validate %Input%

:: Process Input
call :Process %Input%
goto End


:Validate
set "Next=%2"
if not defined App[%1] (
    set "Message=Invalid Input: %1"
    goto Menu
)
if defined Next shift & goto Validate
goto :eof


:Process
set "Next=%2"
call set "App=%%App[%1]%%"

:: Run Installations
:: Specify all of the installations for each app.
:: Step 2. Match on the application names and perform the installation for each
if "%App%" EQU "One" echo Run Install for App One here
if "%App%" EQU "Two" echo Run Install for App Two here
if "%App%" EQU "Three" echo Run Install for App Three here
if "%App%" EQU "Four" echo Run Install for App Four here
if "%App%" EQU "Five" echo Run Install for App Five here
if "%App%" EQU "All Apps" (
    echo Run Install for All Apps here
)

:: Prevent the command from being processed twice if listed twice.
set "App[%1]="
if defined Next shift & goto Process
goto :eof


:End
endlocal
pause >nul

More Related Contents:

  1. Progress bar shows "echo is OFF" message
  2. Why is no string output with ‘echo %var%’ after using ‘set var = text’ command in cmd? [duplicate]
  3. Where does GOTO :EOF return to?
  4. How to set environment variables with spaces?
  5. What are the ERRORLEVEL values set by internal cmd.exe commands?
  6. Split long commands in multiple lines through Windows batch file
  7. How to request Administrator access inside a batch file
  8. Assign command output to variable in batch file
  9. Why are other folder paths also added to system PATH with SetX and not only the specified folder path?
  10. Can I mask an input text in a bat file?
  11. Logical operators (“and”, “or”) in DOS batch
  12. How do you loop in a Windows batch file?
  13. How do I make a batch file terminate upon encountering an error?
  14. Get size of a directory in ‘MB’ using batch file
  15. ERRORLEVEL inside IF
  16. How to write a full path in a batch file having a folder name with space?
  17. batch script – read line by line
  18. How do I compare timestamps of files in a batch script?
  19. How to split double quoted line into multiple lines in Windows batch file?
  20. set /p empty answer crash
  21. Open a URL without using a browser from a batch file
  22. How can I escape an exclamation mark ! in cmd scripts?
  23. How to set a timeout for a process under Windows 7?
  24. Batch – Converting variable to uppercase
  25. Set a path variable with spaces in the path in a Windows .cmd file or batch file
  26. How to store the result of a command expression in a variable using bat scripts?
  27. Get last created directory batch command
  28. How to code a spinner for waiting processes in a Batch file?
  29. Is there a short cut for desktop folder in Windows batch?
  30. Batch file and DEL errorlevel 0 issue

Leave a Comment