Removing blank gap in gnuplot multiplot

by

Getting the margins right with multiplot is a bit tedious, especially when using set pm3d map, which has quite large margins.

Since version 5.0

Since 5.0 version,multiplot has the options margins and spacing.

margins takes four numbers set multiplot margins <left>,<right>,<bottom>,<top>, which give the fixed overall margins around the multiplot layout. spacing takes two number set multiplot spacing <xspacing>,<yspacing> which give the distance between two rows (<yspacing>) or two columns (<xspacing>).

set terminal pngcairo size 800,600 background rgb '#bbbbbb'
set output 'foobar.png'

set multiplot layout 2,2 \
              margins 0.1,0.98,0.1,0.98 \
              spacing 0.08,0.08

set ylabel 'ylabel'
plot x

unset ylabel
plot 2*x

set ylabel 'ylabel'
set xlabel 'xlabel'
plot 3*x

unset ylabel
plot 4*x
unset multiplot

Result (with 5.0rc1):

enter image description here

Earlier versions, kept only for completeness

To achieve the same thing with gnuplot 4.x, you must do the calculations by hand or define some functions, like the following example shows. This should be quite universally usable.

You can put all the general stuff in a configuration file, like multiplot.gp, which contains the functions

init_margins(left, right, bottom, top, dx, dy, rows, cols) = \
  sprintf('left_margin = %f; right_margin = %f; top_margin = %f; bottom_margin = %f; ', left, right, top, bottom) . \
  sprintf('col_count = %d; row_count = %d; gap_size_x = %f; gap_size_y = %f', cols, rows, dx, dy)

get_lmargin(col) = (left_margin + (col - 1) * (gap_size_x + ((right_margin - left_margin)-(col_count - 1) * gap_size_x)/col_count))
get_rmargin(col) = (left_margin + (col - 1) * gap_size_x + col * ((right_margin - left_margin)-(col_count - 1) * gap_size_x)/col_count)
get_tmargin(row) = (top_margin  - (row - 1) * gap_size_y - (row-1) * ((top_margin - bottom_margin  - gap_size_y * row_count) / row_count))
get_bmargin(row) = (top_margin  - (row - 1) * gap_size_y -  row    * ((top_margin - bottom_margin  - gap_size_y * row_count) / row_count))
set_margins(col, row) = \
  sprintf('set lmargin at screen %f;', get_lmargin(col)) . \
  sprintf('set rmargin at screen %f;', get_rmargin(col)) . \
  sprintf('set tmargin at screen %f;', get_tmargin(row)) . \
  sprintf('set bmargin at screen %f;', get_bmargin(row))

The main file is then

set terminal pngcairo size 800,600 background rgb '#bbbbbb'
set output 'foobar2.png'

load 'multiplot.gp'

eval(init_margins(0.1, 0.98, 0.1, 0.98, 0.08, 0.08, 2, 2))    
set multiplot

eval(set_margins(1,1))
set ylabel 'ylabel'
plot x

eval(set_margins(2,1))
unset ylabel
plot 2*x

eval(set_margins(1,2))
set ylabel 'ylabel'
set xlabel 'xlabel'
plot 3*x

eval(set_margins(2,2))
unset ylabel
plot 4*x
unset multiplot

With the result (using 4.6.4):

enter image description here

More Related Contents:

  1. Gnuplot line types
  2. Histogram using gnuplot?
  3. gnuplot: load datafile 1:1 into datablock
  4. Get ratio from 2 files in gnuplot
  5. Loop structure inside gnuplot?
  6. Hatch patterns in gnuplot
  7. Add a single point at an existing plot
  8. How to get the distance between automatic generated gnuplot tics?
  9. pipe plot data to gnuplot script
  10. How to plot data without a separate file by specifying all points inside the Gnuplot script?
  11. multiplot – stacking 3 graphs on a larger canvas
  12. gnuplot 2D polar plot with heatmap from 3D dataset – possible?
  13. How to pass command line argument to gnuplot?
  14. gnuplot: apply colornames from datafile
  15. Making C code plot a graph automatically
  16. How do you plot bar charts in gnuplot?
  17. How to make points one color when a third column equals zero, and another color otherwise, in Gnuplot?
  18. Gnuplot plotting data from a file up to some row
  19. gnuplot linecolor variable in matplotlib?
  20. Line plot in GnuPlot where line color is a third column in my data file?
  21. Gnuplot: conditional plotting ($2 == 15 ? $2 : ‘1/0’) with lines
  22. How do I plot list of tuples in Python?
  23. How to define and access array in GNUplot?
  24. problematic Moire pattern in image produced with gnuplot pm3d and pdf output
  25. Octave-Gnuplot-AquaTerm error: set terminal aqua enhanced title “Figure 1″…unknown terminal type”
  26. Plotting labeled intervals in matplotlib/gnuplot
  27. gnuplot store one number from data file into variable
  28. Gnuplot: How to load and display single numeric value from data file
  29. create heatmap2d from txt file
  30. Fitting a curve to specific data

Leave a Comment