count the number of calls of a clause

by

What you actually want is something slightly different: You want to count the number of answers (so far) of a goal.

The following predicate call_nth(Goal_0, Nth) succeeds like call(Goal_0) but has an additional argument which indicates that the answer found is the n-th answer. This definition is highly specific to SWI or YAP. Do not use things like nb_setarg/3 in your general programs, but use them for well encapsulated cases as this one. Even within
those two systems, the precise meaning of these constructs is not well defined for the general case. Here is a definition for SICStus. Update: use unsigned_64 in newer versions instead of unsigned_32.

call_nth(Goal_0, Nth) :-
   nonvar(Nth),
   !,
   Nth \== 0,
   \+arg(Nth,+ 1,2), % produces all expected errors
   State = count(0,_), % note the extra argument which remains a variable
   Goal_0,
   arg(1, State, C1),
   C2 is C1+1,
   (  Nth == C2
   -> !
   ;  nb_setarg(1, State, C2),
      fail
   ).
call_nth(Goal_0, Nth) :-
   State = count(0,_), % note the extra argument which remains a variable
   Goal_0,
   arg(1, State, C1),
   C2 is C1+1,
   nb_setarg(1, State, C2),
   Nth = C2.

A more robust abstraction is provided by Eclipse:

call_nth(Goal_0, Nth) :-
   shelf_create(counter(0), CounterRef),
   call(Goal_0),
   shelf_inc(CounterRef, 1),
   shelf_get(CounterRef, 1, Nth).

?- call_nth(between(1,5,I),Nth).
I = Nth, Nth = 1 ;
I = Nth, Nth = 2 ;
I = Nth, Nth = 3 ;
I = Nth, Nth = 4 ;
I = Nth, Nth = 5.

So simply wrap it around:

lock_open :-
   call_nth(conditional_combination(X), Nth),
   X = [8,6,5,3,6,9],
   !,
   ....

More Related Contents:

  1. Prolog Accumulators. Are they really a “different” concept?
  2. Way to go from recursion to iteration
  3. Solution for “Fatal error: Maximum function nesting level of ‘100’ reached, aborting!” in PHP
  4. Determining complexity for recursive functions (Big O notation)
  5. Tower of Hanoi: Recursive Algorithm
  6. What is recursion and when should I use it?
  7. How can I make recursive templates in AngularJS when using nested objects?
  8. Is Cmake set variable recursive?
  9. Recursive function causing a stack overflow
  10. “application: not a procedure” in binary arithmetic procedures
  11. recursive variadic template to print out the contents of a parameter pack
  12. Recursion vs loops
  13. How to run array_filter recursively in a PHP array?
  14. Real-world examples of recursion [closed]
  15. I got “scheme application not a procedure” in the last recursive calling of a function
  16. How to count number of element occurrences in a list in Prolog
  17. Implications of foldr vs. foldl (or foldl’)
  18. How does the fibonacci recursive function “work”?
  19. Examples of Recursive functions [closed]
  20. Is it possible to make a recursive closure in Rust?
  21. Prolog find all paths Implementation
  22. What does “Overflow evaluating the requirement” mean and how can I fix it?
  23. SICP recursive process vs iterative process: using a recursive procedure to generate an iterative process
  24. Which recursive functions cannot be rewritten using loops? [duplicate]
  25. Include levels of zero count in result of table()
  26. Prolog: a person is a sibling of himself?
  27. Why are str.count(”) and len(str) giving different output?
  28. Power by squaring for negative exponents
  29. Recursion In Oracle
  30. Fibonacci sequence in Ruby (recursion)

Leave a Comment