File / folder chooser dialog from a Windows batch script

by

File Browser

Update 2016.3.20:

Since PowerShell is a native component of pretty much all modern Windows installations nowadays, I’m declaring the C# fallback as no longer necessary. If you still need it for Vista or XP compatibility, I moved it to a new answer. Starting with this edit, I’m rewriting the script as a Batch + PowerShell hybrid and incorporating the ability to perform multi-select. It’s profoundly easier to read and to tweak as needed.

<# : chooser.bat
:: launches a File... Open sort of file chooser and outputs choice(s) to the console
:: https://stackoverflow.com/a/15885133/1683264

@echo off
setlocal

for /f "delims=" %%I in ('powershell -noprofile "iex (${%~f0} | out-string)"') do (
    echo You chose %%~I
)
goto :EOF

: end Batch portion / begin PowerShell hybrid chimera #>

Add-Type -AssemblyName System.Windows.Forms
$f = new-object Windows.Forms.OpenFileDialog
$f.InitialDirectory = pwd
$f.Filter = "Text Files (*.txt)|*.txt|All Files (*.*)|*.*"
$f.ShowHelp = $true
$f.Multiselect = $true
[void]$f.ShowDialog()
if ($f.Multiselect) { $f.FileNames } else { $f.FileName }

This results in a file chooser dialog.

file chooser

The result of a selection outputs You chose C:\Users\me\Desktop\tmp.txt to the console. If you want to force single file selection, just change the $f.Multiselect property to $false.

(PowerShell command mercilessly leeched from the Just Tinkering Blog.) See the OpenFileDialog Class documentation for other properties you can set, such as Title and InitialDirectory.

Folder Browser

Update 2015.08.10:

Since there is already a COM method for invoking a folder chooser, it’s pretty easy to build a PowerShell one-liner that can open the folder chooser and output the path.

:: fchooser.bat
:: launches a folder chooser and outputs choice to the console
:: https://stackoverflow.com/a/15885133/1683264

@echo off
setlocal

set "psCommand="(new-object -COM 'Shell.Application')^
.BrowseForFolder(0,'Please choose a folder.',0,0).self.path""

for /f "usebackq delims=" %%I in (`powershell %psCommand%`) do set "folder=%%I"

setlocal enabledelayedexpansion
echo You chose !folder!
endlocal

In the BrowseForFolder() method, the fourth argument specifies the root of the hierarchy. See ShellSpecialFolderConstants for a list of valid values.

This results in a folder chooser dialog.

enter image description here

The result of a selection outputs You chose C:\Users\me\Desktop to the console.

See the FolderBrowserDialog class documentation for other properties you can set, such as RootFolder. My original .NET System.Windows.Forms PowerShell and C# solutions can be found in revision 4 of this answer if needed, but this COM method is much easier to read and maintain.

More Related Contents:

  1. FORFILES date -after- (date calc in cmd file)
  2. How to run a PowerShell script within a Windows batch file
  3. Convert a small PS script into a long line in a .BATch file
  4. Determine if windows is currently playing sound
  5. How can I source variables from a .bat file into a PowerShell script?
  6. Batch file v PowerShell script
  7. At which point does `for` or `for /R` enumerate the directory (tree)?
  8. How to do something to each file in a directory with a batch script
  9. Using a custom Tee command for .bat file
  10. Batch script: how to check for admin rights
  11. Setting a system environment variable from a Windows batch file?
  12. Powershell v3 Invoke-WebRequest HTTPS error
  13. Create an empty file on the commandline in windows (like the linux touch command)
  14. What is the proper way to test if a parameter is empty in a batch file?
  15. Using another language (code page) in a batch file made for others
  16. How can I debug a .BAT script?
  17. Start multiple tasks in parallel and wait for them in windows?
  18. Deep copying a PSObject
  19. Can I send some text to the STDIN of an active process under Windows?
  20. Windows 7 theme for WPF?
  21. How to pass environment variables as parameters by reference to another batch file?
  22. Optimum file buffer read size?
  23. Windows shell command to get the full path to the current directory?
  24. PowerShell generic collections
  25. How to check an exchange mailbox via powershell?
  26. Standard Windows menu bars in Windows Forms
  27. Batch program to to check if process exists
  28. Powershell Calling .NET Assembly that uses App.config
  29. ERRORLEVEL vs %ERRORLEVEL% vs exclamation mark ERRORLEVEL exclamation mark
  30. How to get logged-in user’s full name in windows?

Leave a Comment