How to alias a function name in Fortran

by

Yes, Fortran has procedure pointers, so you can in effect alias a function name. Here is a code example which assigns to the function pointer “f_ptr” one function or the other. Thereafter the program can use “f_ptr” and the selected function will be invoked.

module ExampleFuncs

   implicit none

contains

function f1 (x)
  real :: f1
  real, intent (in) :: x

  f1 = 2.0 * x

  return
end function f1


function f2 (x)
   real :: f2
   real, intent (in) :: x

   f2 = 3.0 * x**2

   return
end function f2

end module ExampleFuncs


program test_func_ptrs

    use ExampleFuncs
    implicit none

   abstract interface
      function func (z)
         real :: func
         real, intent (in) :: z
      end function func
   end interface

   procedure (func), pointer :: f_ptr => null ()

   real :: input

   write (*, '( / "Input test value: ")', advance="no" )
   read (*, *) input

   if ( input < 0 ) then
      f_ptr => f1
   else
      f_ptr => f2
   end if

   write (*, '(/ "evaluate function: ", ES14.4 )' )  f_ptr (input)

   stop

end program test_func_ptrs

More Related Contents:

  1. Correct use of modules, subroutines and functions in Fortran
  2. Does Fortran preserve the value of internal variables through function and subroutine calls?
  3. Proper use of modules in Fortran
  4. Value receiver vs. pointer receiver
  5. Passing external function of multiple variables as a function of one variable in Fortran
  6. Computing the cross product of two vectors in Fortran 90
  7. Procedure with assumed-shape dummy argument must have an explicit interface [duplicate]
  8. Changing address contained by pointer using function
  9. Return array in a function
  10. Is passing pointer argument, pass by value in C++?
  11. Define table and column names as arguments in a plpgsql function?
  12. C# Store functions in a Dictionary
  13. Returning a pointer of a local variable C++
  14. Committing transactions while executing a postgreql Function
  15. Non exhaustive pattern in function in GHCi
  16. How is the square root function implemented? [closed]
  17. Function pointer vs Function reference
  18. Static vs class functions/variables in Swift classes?
  19. Whats the difference of functions and methods in Go?
  20. Define a recursive function within a function in Go
  21. Line truncated, Syntax error in argument list
  22. How can I return a character array from a function in C?
  23. Two ways of defining functions in Scala. What is the difference?
  24. Kotlin: How can I create a “static” inheritable function?
  25. use onedit() trigger on a specific sheet within google scripts for google sheets
  26. MsgBox “” vs MsgBox() in VBScript
  27. Function returning array but main showing garbage [duplicate]
  28. Function pointer as a member of a C struct
  29. MATLAB error: Undefined function or method X for input arguments of type ‘double’ [duplicate]
  30. C pointer notation compared to array notation: When passing to function

Leave a Comment