How to test if a path is a file or directory in Windows batch file?

by

I know the if exist path\nul test for a folder used to work on MS-DOS. I don’t know if it was broken with the introduction of long file names.

I knew that if exist "long path\nul" does not work on Windows batch. I did not realize until today that if exist path\nul works on Vista and beyond as long as path is in the short 8.3 form.

The original code appears to work on Vista. It seems like it should work on XP as well, but I believe the following XP bug is getting in the way: Batch parameter %~s1 gives incorrect 8.3 short name.

The original code does not need the FOR loop, it could simply use %~s1

Here is a variation that fully classifies a path as INVALID, FILE or FOLDER. It works on Vista, but does NOT work on XP because of the %~s1 bug. I’m not sure how it performs on MS-DOS.
EDIT 2015-12-08: There are a number of Windows situations where this fails

@echo off
if not exist "%~1" ( set "type=INVALID" ) else if exist %~s1\nul ( set "type=FOLDER" ) else ( set "type=FILE" )
@echo "%~1" = %type%

I believe this variation will work with nearly all versions of Microsoft batch, including MS-DOS and XP. (it obviously won’t work on early versions of DOS that don’t support PUSHD)

@echo off
if exist "%~1" (2>nul pushd "%~1" && (popd&set "type=FOLDER") || set "type=FILE" ) else set "type=INVALID"
echo "%~1" = %type%

UPDATE 2014-12-26

I’m pretty sure the following will work on all versions of Windows from XP onward, but I have only tested on Win 7.
Edit 2015-12-08: This can fail on network drives because the folder test can falsely report a file as a folder

@echo off
if exist %1\ (
  echo %1 is a folder
) else if exist %1 (
  echo %1 is a file
) else (
  echo %1 does not exist
)

UPDATE 2015-12-08

Finally – a test that truly should work on any Windows version from XP onward, including with network drives and UNC paths

for /f "tokens=1,2 delims=d" %%A in ("-%~a1") do if "%%B" neq "" (
  echo %1 is a folder
) else if "%%A" neq "-" (
  echo %1 is a file
) else (
  echo %1 does not exist
)

Note – This technique is intended to be used for a path without any wildcards (a single specific file or folder). If the provided path includes one or more wildcards, then it provides the result for the first file or folder that the file system encounters. Identical directory structures may give different sort order results depending on the underlying file system (FAT32, NTFS, etc.)

More Related Contents:

  1. At which point does `for` or `for /R` enumerate the directory (tree)?
  2. Batch file: Find if substring is in string (not in a file)
  3. Iterate all files in a directory using a ‘for’ loop
  4. Batch character escaping
  5. How to wait all batch files to finish before exiting?
  6. How to do something to each file in a directory with a batch script
  7. How to delete files/subfolders in a specific directory at the command prompt in Windows
  8. Using a custom Tee command for .bat file
  9. Find out if file is older than 4 hours in Batch file
  10. How do I echo and send console output to a file in a bat script?
  11. Set a persistent environment variable from cmd.exe
  12. IF… OR IF… in a windows batch file
  13. Windows batch script to read an .ini file
  14. Copy text from a Windows CMD window to clipboard
  15. Using another language (code page) in a batch file made for others
  16. How can I debug a .BAT script?
  17. Start multiple tasks in parallel and wait for them in windows?
  18. How do I create a shortcut via command-line in Windows?
  19. Counting in a FOR loop using Windows Batch script
  20. cmd is somehow writing Chinese text as output
  21. Special Characters in Batch File
  22. Batch to remove duplicate rows from text file
  23. How to pass environment variables as parameters by reference to another batch file?
  24. Execute multiple batch files concurrently and monitor if their process is completed
  25. Windows shell command to get the full path to the current directory?
  26. Batch goto loses errorlevel
  27. Batch file to upload .txt to FTP
  28. Escape percent signs in given variables
  29. Out of a git console: how do I execute a batch file and then return to git console?
  30. UTF-16 to UTF-8 conversion (for scripting in Windows)

Leave a Comment