How to use QMake’s subdirs template?

by

In addition to Troubadour’s comment, I would note that the SUBDIRS target is only good for specifying subdirectories. Therefore, your extra line of 

SOURCES += main.cpp

in your project.pro file is incorrect, and will likely fail to build your main.cpp file, at worst. At best, qmake will refuse to parse the file, since it has conflicting specifications in it.

I’ve used the SUBDIRS template a few times, and it does well if you can build parts into more-or-less independent libraries, apparently like you have with the logic and the gui separate. Here is one way to do this:

project_dir/
-project.pro
-common.pri
-logic/
----logic.pro
----some logic files
-gui/
----gui.pro
----gui files
-build/
----build.pro
----main.cpp

project.pro:

TEMPLATE = subdirs
SUBDIRS = logic \
          gui

# build must be last:
CONFIG += ordered
SUBDIRS += build

common.pri:

#Includes common configuration for all subdirectory .pro files.
INCLUDEPATH += . ..
WARNINGS += -Wall

TEMPLATE = lib

# The following keeps the generated files at least somewhat separate 
# from the source files.
UI_DIR = uics
MOC_DIR = mocs
OBJECTS_DIR = objs

logic/logic.pro:

# Check if the config file exists
! include( ../common.pri ) {
    error( "Couldn't find the common.pri file!" )
}

HEADERS += logic.h
SOURCES += logic.cpp

# By default, TARGET is the same as the directory, so it will make 
# liblogic.a (in linux).  Uncomment to override.
# TARGET = target

gui/gui.pro:

! include( ../common.pri ) {
    error( "Couldn't find the common.pri file!" )
}

FORMS += gui.ui
HEADERS += gui.h
SOURCES += gui.cpp

# By default, TARGET is the same as the directory, so it will make 
# libgui.a (in linux).  Uncomment to override.
# TARGET = target

build/build.pro:

TEMPLATE = app

SOURCES += main.cpp

LIBS += -L../logic -L../gui -llogic -lgui

# Will build the final executable in the main project directory.
TARGET = ../project

More Related Contents:

  1. How to specify different Debug/Release output directories in QMake .pro file
  2. QMake – how to copy a file to the output
  3. qmake pre-build step before ANY compilation
  4. QMake – How to add and use a variable into the .pro file
  5. Add a define to qmake WITH a value?
  6. C++ Qt – How to add “-std=c++11” to the makefile which is generated by qmake?
  7. How to convert qmake to cmake?
  8. Running a program/script from QMake
  9. How to execute shell command after compile finished from .pro in QT?
  10. Which yocto is best for me
  11. Porting C++ Builder to Qt [closed]
  12. How to make item view render rich (html) text in Qt
  13. Qt Stylesheet for custom widget
  14. Draw Rectangular overlay on QWidget at click
  15. How delete and deleteLater works with regards to signals and slots in Qt?
  16. Undefined reference to vtable. Trying to compile a Qt project
  17. How to set application’s taskbar icon in Windows 7
  18. How to Include OpenSSL in a Qt project
  19. How to build Qt 4.8/5.2 statically under VS2012, using the static MSVC runtime, with Windows XP support?
  20. Access sqlite from a remote server
  21. Understanding form layout mechanisms in Qt
  22. How to make a column in QTableWidget read only?
  23. Why does calling quit() before exec() not quit the application?
  24. Where does Qt Creator save its settings?
  25. How do i resize the contents of a QScrollArea as more widgets are placed inside
  26. How to get STDOUT from a QProcess?
  27. How can I use C++14 features when building qmake projects?
  28. Why should nesting of QEventLoops be avoided?
  29. Qmake: how to remove compiler flag for a certain project, without changing qmake.conf?
  30. How to create scrollbar in QtQuick 2.0?

Leave a Comment