Inno Setup: Extending Windows default apps list

by

For generic information, see:

In Inno Setup, you implement this using [Registry] section:

[Registry]
; Create the application capability key
; (The location of the key does not matter)
Root: HKLM; Subkey: "Software\My Company"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\My Company\My Program"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\My Company\My Program\Capability"; \
    ValueType: string; ValueName: "ApplicationDescription"; \
    ValueData: "This is My Program that does stuff"; Flags: uninsdeletevalue
Root: HKLM; Subkey: "Software\My Company\My Program\Capability"; \
    ValueType: string; ValueName: "ApplicationName"; ValueData: "My Program"; \
    Flags: uninsdeletevalue
; List of extensions the application supports
Root: HKLM; \
    Subkey: "Software\My Company\My Program\Capability\FileAssociations"; \
    ValueType: string; ValueName: ".jpg"; ValueData: "MyProgram.JPEG"; \
    Flags: uninsdeletevalue

; Add the capability key to list of registered applications
Root: HKLM; Subkey: "Software\RegisteredApplications"; \
    ValueType: string; ValueName: "My Program"; \
    ValueData: "Software\My Company\My Program\Capability"; \
    Flags: uninsdeletevalue

; For each extension that the application supports
Root: HKCR; Subkey: "MyProgram.JPEG"; Flags: uninsdeletekeyifempty
Root: HKCR; Subkey: "MyProgram.JPEG"; \
    ValueType: string; ValueName: ""; ValueData: "MyProgram JPEG"; \
    Flags: uninsdeletevalue
Root: HKCR; Subkey: "MyProgram.JPEG\DefaultIcon"; Flags: uninsdeletekeyifempty
Root: HKCR; Subkey: "MyProgram.JPEG\DefaultIcon"; \
    ValueType: string; ValueName: ""; ValueData: "{app}\MyProg.exe,1"; \
    Flags: uninsdeletevalue
Root: HKCR; Subkey: "MyProgram.JPEG\Shell"; Flags: uninsdeletekeyifempty
Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open"; Flags: uninsdeletekeyifempty
Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open\Command"; \
    Flags: uninsdeletekeyifempty
Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open\Command"; \
    ValueType: string; ValueName: ""; ValueData: """{app}\MyProg.exe"" ""%1"""; \
    Flags: uninsdeletevalue

In Inno Setup 6, you should modify the code as follows to support non-administrative install mode:

  1. Replace HKLM in the first block with HKA;
  2. Replace HKCR with HKA and add the Software\Classes\ prefix to the Subkey in the second block.

Set Default Programs

Set Program Associations

More Related Contents:

  1. non resizable window border and positioning
  2. Failed to load the JNI shared Library (JDK)
  3. What’s the best way to distribute Java applications? [closed]
  4. How to bring a window to the front?
  5. How to stop java process gracefully?
  6. Reliable File.renameTo() alternative on Windows?
  7. Downloading Java JDK on Linux via wget is shown license page instead
  8. How do I find where JDK is installed on my windows machine?
  9. How to update PATH variable permanently from Windows command line?
  10. How to do a true Java ping from Windows?
  11. Run Java application at Windows startup
  12. Java Thread priority has no effect
  13. How to find and kill running Win-Processes from within Java?
  14. Could not find or load main class
  15. Windows: how to get a list of all visible windows?
  16. Java 7 default locale
  17. how to detect operating system language (locale) from java code
  18. How can I add a context menu to the Windows Explorer for a Java application?
  19. “Hello world” Android app with as few files as possible, no IDE, and text editor only
  20. Validate a file name on Windows
  21. TestSuite Setup in jUnit 4
  22. Windows 7 Taskbar Progress Bar in Java
  23. Simple Java program 100 times slower after plugging in USB hotspot
  24. Error in setting JAVA_HOME
  25. How to kill a process in Java, given a specific PID
  26. Reading Windows file summary properties (title, subject, author) in Java
  27. Create Windows Installer for Java Programs [closed]
  28. Knowing which java.exe process to kill on a windows machine [closed]
  29. Can’t get past 2542 Threads in Java on 4GB iMac OSX 10.6.3 Snow Leopard (32bit)
  30. Powershell: Capturing standard out and error with Process object

Leave a Comment