Variables are not behaving as expected

by

You are not the first, who fell into the famous “delayed expansion trap” (and you won’t be the last).

You need delayed expansion if you want to use a variable, that you changed in the same block (a block is a series of commands within parentheses (and )).

Delayed variables are referenced with !var! instead of %var%.

Reason is the way, cmd parses the code. A complete line or block is parsed at once, replacing normal variables with their value at parse time. Delayed variables are evaluated at runtime.

Two simple batch files to demonstrate:

setlocal EnableDelayedExpansion
set "var=hello"
if 1==1 (
    set "var=world"
    echo %var% !var!
)

setlocal EnableDelayedExpansion
for /L %%i in (1,1,5) do (
    echo %random% !random!
)

Note: A line is also treated as a block:

set "var=old"
set "var=new" & echo %var%

With delayed expansion:

setlocal EnableDelayedExpansion
set "var=old"
set "var=new" & echo !var!

Delayed expansion is per default turned off at the command prompt. If you really need it, you can do:

cmd /V:ON /C "set "var=hello" & echo !var!"

Also there is a way to do the same without delayed expansion (but call costs some time, so it’s slower, but if for some reason you can’t / don’t want to use delayed expansion, it’s an alternative):

setlocal DISabledelayedexpansion
for /L %%i in (1 1 5) do (
    call echo %random% %%random%% 
)

Both methods can also be used to display array-like variables:

(This is often asked like “variable which contains another variable” or “nested variables”)

Here is a collection for using such array-like variables in different situations:

With delayed expansion:

setlocal ENableDelayedExpansion
set "num=4"
set "var[%num%]=HELLO"
echo plain delayed: !var[%num%]!
for /L %%i in (4 1 4) do (
    echo for delayed: !var[%%i]!
    set a=%%i
    call echo for delayed with variable: %%var[!a!]%%
)

without delayed expansion:

setlocal DISableDelayedExpansion
set "num=4"
set "var[%num%]=HELLO"
call echo plain called: %%var[%num%]%%
for /L %%i in (4 1 4) do (
    call echo FOR called: %%var[%%i]%%
    set a=%%i
    call echo FOR called with variable: %%var[%a%]%%
)

Note: setlocal has no effect outside of batchfiles, so delayedexpansion works only:

  • In batch files
  • When the cmd was started with delayed expansion enabled (cmd /V:ON) (by default, the cmd runs with delayed expansion disabled)

(Follow the links, when you are interested in the technical background or even the advanced technical stuff)

More Related Contents:

  1. Example of delayed expansion in batch file
  2. Windows Batch Variables Won’t Set
  3. Setting a system environment variable from a Windows batch file?
  4. windows batch SET inside IF not working
  5. Set a persistent environment variable from cmd.exe
  6. How can I source variables from a .bat file into a PowerShell script?
  7. How do I get current date/time on the Windows command line in a suitable format for usage in a file/folder name?
  8. Symbol equivalent to NEQ, LSS, GTR, etc. in Windows batch files
  9. At which point does `for` or `for /R` enumerate the directory (tree)?
  10. How to do something to each file in a directory with a batch script
  11. How to delete files/subfolders in a specific directory at the command prompt in Windows
  12. How do I escape ampersands in batch files?
  13. Using a custom Tee command for .bat file
  14. Batch script: how to check for admin rights
  15. How to correct variable overwriting misbehavior when parsing output?
  16. FORFILES date -after- (date calc in cmd file)
  17. Using another language (code page) in a batch file made for others
  18. How can I debug a .BAT script?
  19. Start multiple tasks in parallel and wait for them in windows?
  20. How do I create a shortcut via command-line in Windows?
  21. Why does findstr not handle case properly (in some circumstances)?
  22. Batch script with for loop and pipe
  23. Execute multiple batch files concurrently and monitor if their process is completed
  24. Windows shell command to get the full path to the current directory?
  25. How to read input from console in a batch file?
  26. Batch goto loses errorlevel
  27. I need to match or replace an asterisk * in a batch environmental variable using only native Windows commands. Is this possible?
  28. Escape percent signs in given variables
  29. Out of a git console: how do I execute a batch file and then return to git console?
  30. UTF-16 to UTF-8 conversion (for scripting in Windows)

Leave a Comment