Common Types of Subversion Hooks

by

I am using the pre-revprop-change hook that allows me to actually go back and edit comments and such information after the commit has been performed. This is very useful if there is missing/erroneous information in the commit comments.

Here I post a pre-revprop-change.bat batch file for Windows NT or later. You
can certainly enhance it with more modifications. You can also derive a
post-revprop-change.cmd from it to back up the old snv:log somewhere or just to append it to the new log.

The only tricky part was to be able to actually parse the stdin from
the batch file. This is done here with the FIND.EXE command.

The other thing is that I have had reports from other users of issues with the use of the /b with the exit command. You may just need to remove that /b in your specific application if error cases do not behave well.

@ECHO OFF

set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow changes to svn:log. The author, date and other revision
:: properties cannot be changed
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow modifications to svn:log (no addition/overwrite or deletion)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%action%'=='M' goto ERROR_ACTION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Make sure that the new svn:log message contains some text.
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
 set bIsEmpty=false
)
if '%bIsEmpty%'=='true' goto ERROR_EMPTY

goto :eof



:ERROR_EMPTY
echo Empty svn:log properties are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

More Related Contents:

  1. How do I migrate an SVN repository with history to a new Git repository?
  2. How do I ignore a directory with SVN?
  3. Checkout one file from Subversion
  4. Do I really need version control? [closed]
  5. How does Git solve the merging problem? [closed]
  6. Why is branching and merging easier in Mercurial than in Subversion?
  7. How do you organize your version control repository?
  8. Why should I use version control? [closed]
  9. Structure of Projects in Version Control
  10. Best general SVN Ignore Pattern?
  11. How do you deal with configuration files in source control?
  12. SVN pre-commit hook for avoiding changes to tags subdirectories
  13. To put the prefix ? to codes by Git/SVN
  14. What are the relative strengths and weaknesses of Git, Mercurial, and Bazaar? [closed]
  15. Are subversion externals an antipattern?
  16. Externalising SCM credentials with Maven
  17. Is there a Subversion Checkout Hook or something similar?
  18. How to version control config files pragmatically?
  19. How to use SVN, Branch? Tag? Trunk? [closed]
  20. How do I get a list of all unversioned files from SVN?
  21. Dealing with SVN keyword expansion with git-svn
  22. Delete file with all history from svn repository
  23. What makes some version control systems better at merging?
  24. How do I create a branch?
  25. How can I force subversion to commit an unchanged file?
  26. Handling renames: svn vs. git vs. mercurial
  27. Should I store all projects in one repository or multiple?
  28. How would you organize a Subversion repository for in house software projects?
  29. Moving SVN repositories data with history as subfolders into another repository
  30. How to synchronize two Subversion repositories?

Leave a Comment