Compare values of two arrays – classic asp

by

This function:

Function diffArray( aA, aB )
  ' !! http://en.wikipedia.org/wiki/Union_%28set_theory%29
  ' The union of two sets A and B is the collection of points which are in A or
  ' in B (or in both)
  Dim dicU : Set dicU = CreateObject( "Scripting.Dictionary" )
  ' !! http://en.wikipedia.org/wiki/Intersection_%28set_theory%29
  ' the intersection of two sets A and B is the set that contains all elements
  ' of A that also belong to B (or equivalently, all elements of B that also
  ' belong to A)
  Dim dicI : Set dicI = CreateObject( "Scripting.Dictionary" )
  ' !! http://en.wikipedia.org/wiki/Complement_%28set_theory%29
  ' If A and B are sets, then the relative complement of A in B, also known as
  ' the set-theoretic difference of B and A, is the set of elements in B, but
  ' not in A. The relative complement of A in B is denoted B \ A
  Dim dicAB : Set dicAB = CreateObject( "Scripting.Dictionary" )
  Dim dicBA : Set dicBA = CreateObject( "Scripting.Dictionary" )
  Dim vItem
  For Each vItem In aA
      dicU(  vItem ) = 0 ' all from A go into UNI (all from B added later)
      dicAB( vItem ) = 0 ' all from A go into A\B (all from B removed later)
  Next
  For Each vItem In aB
      dicU( vItem ) = 0 ' all from B are added to UNI
      If dicAB.Exists( vItem ) Then ' B item found in (current) A\B
         dicI( vItem ) = 0 ' goes into INT
         dicAB.Remove vItem ' and must be removed from A\B
      Else ' B item not fount in (current) A\B
         If Not dicI.Exists( vItem ) Then dicBA( vItem ) = 0 ' goes to B/A if not already in INT
'        dicBA( vItem ) = 0 ' bug: would add item previously removed from A\B to INT
      End If
  Next
  diffArray = Array( dicU.Keys, dicI.Keys, dicAB.Keys, dicBA.Keys )
End Function

avoids the N*N loopings of D-Money’s proposal. (BTW: The fact that in VBScript
you specify the size of an array by giving its UBound (last index) may surprise
users of other languages, but that does not justify code that fails if arrays don’t
have spurious tails.)

Code to demonstrate that function:

  Dim aA   : aA   = Split( "85 459 90 85" )
  Dim aB   : aB   = Split( "4711 459 90 4711" )
  Dim aRes : aRes = diffArray( aA, aB )
  WScript.Echo "A  :", Join( aA )
  WScript.Echo "B  :", Join( aB )
  WScript.Echo "UNI:", Join( aRes( 0 ) ), "in A or B"
  WScript.Echo "INT:", Join( aRes( 1 ) ), "in A and B"
  WScript.Echo "A\B:", Join( aRes( 2 ) ), "in A but not in B"
  WScript.Echo "B\A:", Join( aRes( 3 ) ), "in B but not in A"

Output:

A  : 85 459 90 85
B  : 4711 459 90 4711
UNI: 85 459 90 4711 in A or B
INT: 459 90 in A and B
A\B: 85 in A but not in B
B\A: 4711 in B but not in A

For another sample use, see this question.

More Related Contents:

  1. Compare arrays in swift
  2. How can a slice contain itself?
  3. Please help me access nested array
  4. remove an index number from array
  5. Sort array of objects by string property value
  6. Reading output of a command into an array in Bash
  7. Passing arrays as parameters in bash
  8. Creating an Array from a Range in VBA
  9. Element-wise array replication in Matlab
  10. Select the values of one property on all objects of an array in PowerShell
  11. Iterate over two arrays simultaneously in bash
  12. What is the ideal growth rate for a dynamically allocated array?
  13. Two-dimensional array in Swift
  14. How to iterate over array of objects in Handlebars?
  15. 1D Number Array Clustering
  16. Creating Indicator Matrix
  17. How to initialize two-dimensional arrays in Fortran
  18. Array of Matrices in MATLAB
  19. Why have arrays in Go?
  20. Print array elements on separate lines in Bash?
  21. How to check identical array in most efficient way? [duplicate]
  22. Swift 3 2d array of Int
  23. How can I interleave two arrays?
  24. How is the array stored in memory?
  25. Maximum single-sell profit
  26. Unmarshal 2 different structs in a slice
  27. Swift: What’s the best way to pair up elements of an Array
  28. Why are Arrays invariant, but Lists covariant?
  29. list items are not deleting properly (React)
  30. A different way to malloc a 2D array?

Leave a Comment