Echoing a URL in Batch

by

You have not shown us full batch code and therefore I have to guess for reason of variable HTMLPGnr being not defined on reference.

DelayedExpansion is on during the defining of the variable and off when using it.

That sentence let me think of something like following was used in your batch file:

setlocal EnableDelayedExpansion
if HTMLPGnr==1 set /a HTMLNxtpg=2 
if HTMLPGnr==2 set /a HTMLNxtpg=3
if HTMLPGnr==3 set /a HTMLNxtpg=4
if HTMLPGnr==4 set /a HTMLNxtpg=5
if HTMLPGnr==5 set /a HTMLNxtpg=6
if HTMLPGnr==6 set /a HTMLNxtpg=1
endlocal
echo ^<body onload="timer=setTimeout(function(){ window.location='file:///C:/Users/MyUser/Dropbox/Netpage/sources/Page/Page_%HTMLNxtpg%.html';}, %HTMLlen%)" style="background:#408CBD"^>>>sources/Page/Page_%HTMLPGnr%.html

The command setlocal with parameter EnableDelayedExpansion does not only enable delayed environment variable expansion, it makes also a copy of the current environment table.

Every set command modifies the environment variables in the new table. The previous environment variable table is kept in memory in the meantime unmodified. So changing values of already existing environment variables or adding environment variables is done only on the new table.

The command endlocal restores previous mode of delayed expansion which means usually turning it off. And additionally also the current environment variable table is discarded and previous table is restored from memory.

So all set operations resulting in adding, deleting or modifying variables between setlcoal and endlocal are lost after command endlocal.

As variable HTMLNxtpg is created completely useless in a new table with enabled delayed expansion and also useless option /a, this variable is not existing anymore after command endlocal.

As Stephan suggested, those 9 lines of code can be replaced by following 2 lines:

set /a HTMLNxtpg=HTMLPGnr %% 6 + 1
echo ^<body onload="timer=setTimeout(function(){ window.location='file:///C:/Users/MyUser/Dropbox/Netpage/sources/Page/Page_%HTMLNxtpg%.html';}, %HTMLlen%)" style="background:#408CBD"^>>>sources/Page/Page_%HTMLPGnr%.html

But let us look on setlocal and endlocal behavior on a simple example:

@echo off
set "TEST=Hi!"
echo  1. !TEST!
echo  2. %TEST%
setlocal EnableDelayedExpansion
echo  3. !TEST!
echo  4. %TEST%
set "TEST=Hello^!"
echo  5. !TEST!
echo  6. %TEST%
setlocal DisableDelayedExpansion
echo  7. !TEST!
echo  8. %TEST%
set "TEST=Bonjour!"
echo  9. !TEST!
echo 10. %TEST%
endlocal
echo 11. !TEST!
echo 12. %TEST%
endlocal
echo 13. !TEST!
echo 14. %TEST%
set "TEST="
pause

Running this batch file results in the output:

 1. !TEST!
 2. Hi!
 3. Hi!
 4. Hi
 5. Hello!
 6. Hello
 7. !TEST!
 8. Hello!
 9. !TEST!
10. Bonjour!
11. Hello!
12. Hello
13. !TEST!
14. Hi!
  1. !TEST! is output as delayed environment variable expansion is not enabled by default.
  2. Hi! is correct output on referencing value of variable TEST normally while delayed expansion not being enabled.
  3. Hi! is output now with referencing value of variable TEST with delayed expansion because delayed expansion is now enabled and the variable still exists because a copy of entire table was made before.
  4. Hi without explanation mark is output on referencing value of variable TEST normally because of exclamation mark is interpreted by command line interpreter as beginning of a delayed variable reference.
  5. Hello! is correct output with delayed expansion after modifying the variable TEST.
    The modification needs to be done with escaping the exclamation mark as otherwise command line interpreter would interpret ! again as beginning of a delayed expanded variable reference on assigning the new string to variable TEST.
  6. Hello without exclamation mark is output on referencing new value of TEST normally for same reason as before.
  7. !TEST! is output as delayed environment variable expansion is disabled again.
  8. Hello! is the correct output for TEST after disabling delayed expansion and creating one more copy of entire environment variables table.
  9. !TEST! is output as delayed environment variable expansion is still disabled although value of TEST was changed once more.
  10. Bonjour! is the correct output for value of third instance of TEST.
  11. Hello! is output after endlocal which discarded third table and restored also delayed expansion mode.
  12. Hello indicates also that delayed expansion is again active for second table because exclamation mark is again not output.
  13. !TEST! is output because after one more endlocal the second table is also discarded and we are back on initial table with delayed expansion being disabled again.
  14. Hi! is the final output on referencing value of first instance of TEST normally before deleting this variable.

I hope, this simple example helps to understand what the commands setlocal and endlocal do.

More Related Contents:

  1. Grid or Table? for Text and an Image on the bottom right (4/4) [duplicate]
  2. How do I disable the resizable property of a textarea?
  3. Center image using text-align center?
  4. Can an Option in a Select tag carry multiple values?
  5. Show an image preview before upload
  6. Make a div fill the height of the remaining screen space
  7. What’s HTML character code 8203?
  8. How can I combine flexbox and vertical scroll in a full-height app?
  9. Why does HTML5 form-validation allow emails without a dot?
  10. How to position two elements side by side using CSS
  11. Set HTML5 doctype with XSLT
  12. How do I use HTML as the view engine in Express?
  13. Protect image download
  14. Hiding elements in responsive layout?
  15. Testing HTML email rendering [closed]
  16. Set date input field’s max date to today
  17. How to make in CSS an overlay over an image?
  18. Html Video player plays sound but not video
  19. How to decode HTML Entities in C?
  20. How to handle html5 constraint validation pop-up using Selenium?
  21. Why isn’t my margin working with position: fixed?
  22. How to align input forms in HTML
  23. Thymeleaf – How to add checked attribute to input conditionally
  24. Create links in HTML canvas
  25. Using rvest or httr to log in to non-standard forms on a webpage
  26. HTML – Why boolean attributes do not have boolean value?
  27. Zoom changes the design layout
  28. Clear Canvas Rect (but keep background)
  29. CSS After Element to insert mailto link?
  30. Which browsers support data URIs and since which version?

Leave a Comment