Having multiple Excel instances launched, how can I get the Application Object for all of them?

by

To list the running instances of Excel:

#If VBA7 Then
  Private Declare PtrSafe Function AccessibleObjectFromWindow Lib "oleacc" ( _
    ByVal hwnd As LongPtr, ByVal dwId As Long, riid As Any, ppvObject As Object) As Long

  Private Declare PtrSafe Function FindWindowExA Lib "user32" ( _
    ByVal hwndParent As LongPtr, ByVal hwndChildAfter As LongPtr, _
    ByVal lpszClass As String, ByVal lpszWindow As String) As LongPtr
#Else
  Private Declare Function AccessibleObjectFromWindow Lib "oleacc" ( _
    ByVal hwnd As Long, ByVal dwId As Long, riid As Any, ppvObject As Object) As Long

  Private Declare Function FindWindowExA Lib "user32" ( _
    ByVal hwndParent As Long, ByVal hwndChildAfter As Long, _
    ByVal lpszClass As String, ByVal lpszWindow As String) As Long
#End If

Sub Test()
  Dim xl As Application
  For Each xl In GetExcelInstances()
    Debug.Print "Handle: " & xl.ActiveWorkbook.FullName
  Next
End Sub

Public Function GetExcelInstances() As Collection
  Dim guid&(0 To 3), acc As Object, hwnd, hwnd2, hwnd3
  guid(0) = &H20400
  guid(1) = &H0
  guid(2) = &HC0
  guid(3) = &H46000000

  Set GetExcelInstances = New Collection
  Do
    hwnd = FindWindowExA(0, hwnd, "XLMAIN", vbNullString)
    If hwnd = 0 Then Exit Do
    hwnd2 = FindWindowExA(hwnd, 0, "XLDESK", vbNullString)
    hwnd3 = FindWindowExA(hwnd2, 0, "EXCEL7", vbNullString)
    If AccessibleObjectFromWindow(hwnd3, &HFFFFFFF0, guid(0), acc) = 0 Then
      GetExcelInstances.Add acc.Application
    End If
  Loop
End Function

More Related Contents:

  1. How do you change the value of a cell in excel by clicking on it using VBA? [closed]
  2. How to avoid using Select in Excel VBA
  3. How do I use FileSystemObject in VBA?
  4. Is the . in .Range necessary when defined by .Cells?
  5. Run Excel Macro from Outside Excel Using VBScript From Command Line
  6. How to put a tooltip on a user-defined function
  7. If WorkSheet(“wsName”) Exists [duplicate]
  8. VBA Shell function in Office 2011 for Mac
  9. How to copy sheets to another workbook using vba?
  10. Check if value exists in column in VBA
  11. hiding formulas in formula bar
  12. How to delete multiple rows without a loop in Excel VBA
  13. VBA Many buttons point to the same _Click sub
  14. Excel VBA Filter Change event handler
  15. How to suppress Update Links warning?
  16. How do we use restful APIs from Excel macros (vba)?
  17. Cannot VBA write data to cells in Excel 2007/2010 within a function
  18. VBA paste as values – how to
  19. How to send email to multiple recipients with addresses stored in Excel?
  20. What are the benefits of using Classes in VBA? [closed]
  21. Writing a VLOOKUP function in vba
  22. Handle cancellation of InputBox to select range
  23. Type Mismatch in Loop to scan Outlook Messages [duplicate]
  24. VBA: How to combine two ranges on different sheets into one, to loop through
  25. Excel VBA – select multiple columns not in sequential order
  26. Application.WorksheetFunction.Match method
  27. Excel Hide/Show all tabs on Ribbon except custom tab
  28. Macros Not Showing Up in Macro Table
  29. Excel telling me my blank cells aren’t blank
  30. Excel VBA Run-time Error ‘32809’ – Trying to Understand it

Leave a Comment