How do YOU manage Perl modules when using a package manager?

by

For development, I install my own Perl and leave the system Perl alone. If I want to upgrade the system Perl, I use the system package manager. For my development Perl, I use the cpan tool.

Since I keep those separate, I should never mess up the Perl that the system needs for its maintenance tasks and so on, but I don’t have to rely on the system’s decisions for development.

It’s very easy to install separate Perls. When you run Configure from the source distribution, it will ask you where you want to install everything. Give it any path that you like. I have many Perls installed in /usr/local/perls, for instance, and everything for each installation lives separately. I then make symlinks in /usr/local/bin for them (e.g. perl5.8.9, perl.5.10.0, perl5.10.0-threaded). When I want a particular version, I just use the one I want:

$ perl5.10.0 program.pl

The particular binary ensures that the program picks up the right module search path and so on (it’s the same stuff in the Config.pm module for that binary).

Here’s a script I use to create the symlinks. It looks in the bin directory, figures out the Perl version, and makes links like cpan5.10.1 and so on. Each program already knows the right perl to call: 

#!perl

use 5.010;

use strict;
use warnings;

use File::Basename;
use File::Spec::Functions;

my $perls_directory = catfile(
    $ARGV[0] // '/usr/local/perls', 
    'perl*'
);
die "$perls_directory does not exist!\n" 
    unless -d dirname $perls_directory;

my $links_directory = $ARGV[1] // catfile( $ENV{HOME}, 'bin' ); #/
die "$links_directory does not exist!\n" unless -d $links_directory;

foreach my $directory ( glob( $perls_directory ) )
{
    say "Processing $directory...";

    unless( -e catfile( $directory, 'bin' ) )
    {
        say "\tNo bin/ directory. Skipping!";
        next;
    }

    my @perls = glob( catfile( $directory, qw( bin perl5* ) ) );    

    my( $perl_version ) = $perls[0] =~ m/(5\.\d+\.\d+)\z/;
    say "\tperl version is $perl_version";

    foreach my $bin ( glob( catfile( $directory, 'bin', '*' ) ) )
    {
        say "\tFound $bin";
        my $basename = basename( $bin );

        my $link_basename = do {
            if( $basename =~ m/5\.\d+\.\d+\z/) { $basename }
            else                               { "$basename$perl_version" }
        };

        my $link = catfile( $links_directory, $link_basename );
        next if -e $link;
        say "\t\tlinking $bin => $link";
        symlink $bin => $link or
            warn "\t\tCould not create symlink [$!]: $bin => $link!";
    }
}

Everything gets install in the right place for that particular Perl.

I’ve also been thinking that I should put those Perl directories under some sort of source control. If I add a module I don’t like, I just back out to an earlier revision. I’m only starting to do that though and haven’t played with it much.

I’ve written more about this sort of thing in the Effective Perler blog:

More Related Contents:

  1. How can I install a CPAN module into a local directory?
  2. How can I install Perl modules without root privileges?
  3. How can I use a new Perl module without install permissions?
  4. Fastest way to find lines of a file from another larger file in Bash
  5. How can I quickly sum all numbers in a file?
  6. How can I delete a newline if it is the last character in a file?
  7. How can I run a Perl script as a system daemon in linux?
  8. How do I configure Apache 2 to run Perl CGI scripts?
  9. Get the Perl rename utility instead of the built-in rename
  10. Perl command line multi-line replace
  11. extracting unique values between 2 sets/files
  12. How do I choose a package name for a custom Perl module that does not collide with builtin or CPAN packages names?
  13. How can I install a specific version of a set of Perl modules?
  14. kernel symbol marked with “T” in /proc/kallsyms is not exported
  15. How can I find the version of an installed Perl module?
  16. understanding and decoding the file mode value from stat function output
  17. How to declare 2D array in bash
  18. how to install gcc 4.9.2 on RHEL 7.4
  19. What happens if there is no exit system call in an assembly program?
  20. equivalent date from GNU to solaris
  21. How to restrict SSH users to a predefined set of commands after login?
  22. Bash prompt with the last exit code
  23. Round a divided number in Bash
  24. How can I programmatically manage iptables rules on the fly?
  25. Add a newline only if it doesn’t exist
  26. How is the Linux kernel tested?
  27. Count number of files within a directory in Linux? [closed]
  28. How to check if X server is running?
  29. Best way to script remote SSH commands in Batch (Windows)
  30. OpenGL without X.org in linux

Leave a Comment