How to split double quoted line into multiple lines in Windows batch file?

by

I see three possible workarounds.

1) Building the line combining multiple for-parameters. 

@echo off
SETLOCAL EnableDelayedExpansion

set "line="
for %%a in ("line1" 
"line2"
"line3"
"line4"
) do set line=!line!%%~a
echo !line!

Drawback: It drops lines, when there is a ? or * in the text.

2) Leaving the “quote” at the end of each line

@echo on
SETLOCAL EnableDelayedExpansion

set "line=line1 & x#"^
 "line2 & a#"^
 "line3 & b #"^
 "line4 & c "

set "line=!line:#" "=!"
echo !line!

The first space in each line is important, because the caret works as multiline character but it also escapes the first character, so also a quote would be escaped.
So I replace the unnessary #” ” after building the line.

EDIT Added: 3) Disappearing quotes

setlocal EnableDelayedExpansion
echo "A very long line I want to !="!^
split into two lines"

In my opinion this is the best way, it works as the parser first see the quotes and therefore the last caret will work, as it seems to be outside of the quotes.
But this !="! expression will expand the variable named =", but such a variable name can’t exists (an equal sign can’t occur as first character) so it expands to nothing.

You can also create safe expressions, they will always escape out of quotes, independent if there is a quote or not in the line.
!="^"!

echo This multiline works !="^"!^
as expected
echo "This multiline works !="^"!^
too"

If you want avoid delayed expansion, you could also use a -FOR-Loop like

for %%^" in ("") do (
echo "This multiline works %%~"^
too"
)

More Related Contents:

  1. Move files to a categorically numbered ‘bucket’ folders
  2. How can I pass arguments to a batch file?
  3. Press Keyboard keys using a batch file [closed]
  4. Displaying Windows command prompt output and redirecting it to a file
  5. Defining and using a variable in batch file
  6. Explain how Windows batch newline variable hack works
  7. Windows Bat file optional argument parsing
  8. What is the best way to do a substring in a batch file?
  9. How to replace substrings in windows batch file
  10. using batch echo with special characters
  11. How to set a variable inside a loop for /F
  12. How do I get the IP address into a batch-file variable?
  13. BATCH file asks for file or folder [duplicate]
  14. creating a shortcut for a exe from a batch file
  15. Floating point division in a batch file
  16. How to set PATH environment variable in batch file only once on Windows?
  17. why is my cd %myVar% being ignored?
  18. How to run a “.bat” file during installation?
  19. Batch file to copy directories recursively
  20. Random generator in the batch
  21. Batch Files – Error Handling
  22. How to automatically close cmd window after batch file execution?
  23. Save and Load .bat game
  24. How can I add greater than and less than into a batch file variable
  25. Set a path variable with spaces in the path in a Windows .cmd file or batch file
  26. How to store the result of a command expression in a variable using bat scripts?
  27. Get last created directory batch command
  28. How to code a spinner for waiting processes in a Batch file?
  29. Is there a short cut for desktop folder in Windows batch?
  30. Batch file and DEL errorlevel 0 issue

Leave a Comment