why is my cd %myVar% being ignored?

by

1. Quoting unknown paths

Paths not known on running a batch file and not being fixed could contain 1 or more spaces. This means path strings should be quoted like file names.

2. Change drive and directory

Command CD changes by default the current directory on current drive only.

Option /D to change current directory to a directory on any drive with a letter should be always used when current directory on starting a batch file is not fixed on same drive as temporarily used current directory.

3. setlocal and endlocal save and restore also current directory

The command setlocal creates always a new copy of the environment table which is destroyed when using endlocal or exiting the batch file restoring previous table. Also the states of command extensions and delayed expansion is saved and restored. See this answer with an example demonstrating what happens on using setlocal and endlocal.

But additionally setlocal saves also current directory and endlocal restores it as the following code demonstrates.

@echo off
set "InitialPath=%CD%"
echo 1. Current directory is: %CD%
cd /D "%windir%\Temp"
echo 2. Current directory is: %CD%
setlocal
rem Change current directory to parent directory.
cd ..\
echo 3. Current directory is: %CD%
setlocal
rem Change current directory to root of current drive.
cd \
echo 4. Current directory is: %CD%
endlocal
echo 5. Current directory is: %CD%
endlocal
echo 6. Current directory is: %CD%
cd /D "%InitialPath%"
echo 7. Current directory is: %CD%
set "InitialPath="
pause

4. Trailing spaces and tabs assigned to environment variable

With not using double quotes on assigning a value to an environment variable, command set appends everything after first equal sign up to end of line to the environment variable including not visible trailing spaces and tabs. There are trailing spaces on line set originalPath=%~dp0  , see answer on Why is no string output with ‘echo %var%’ after using ‘set var = text’ on command line? for more details.

Your code improved to avoid all the possible issues listed above:

@echo off
set "myPath=Subfolder1"
set "folderList=input.txt"
REM set "originalPath=%CD%"
set "originalPath=%~dp0"

REM pushd "%myPath%"
cd /D "%myPath%"
setlocal EnableDelayedExpansion

:process
REM The rest of my script

endlocal
echo %originalPath%
REM echo %originalPath% prints: C:\BatchTests\
cd /D "%originalPath%"
REM popd
pause

And taking point 3 into account and as aschipfl also explained well, following would work, too.

@echo off
set "myPath=Subfolder1"
set "folderList=input.txt"

setlocal EnableDelayedExpansion
cd /D "%myPath%"

:process
REM The rest of my script

endlocal
pause

More Related Contents:

  1. Move files to a categorically numbered ‘bucket’ folders
  2. How can I pass arguments to a batch file?
  3. Displaying Windows command prompt output and redirecting it to a file
  4. Defining and using a variable in batch file
  5. Explain how Windows batch newline variable hack works
  6. Windows Bat file optional argument parsing
  7. What is the best way to do a substring in a batch file?
  8. How to replace substrings in windows batch file
  9. How to set a variable inside a loop for /F
  10. Run Batch File On Start-up
  11. How do I get the IP address into a batch-file variable?
  12. creating a shortcut for a exe from a batch file
  13. Comparing two number in batch script
  14. Floating point division in a batch file
  15. How to set PATH environment variable in batch file only once on Windows?
  16. Batch file to copy directories recursively
  17. Random generator in the batch
  18. Batch Files – Error Handling
  19. Multiple choices menu on batch file?
  20. How to automatically close cmd window after batch file execution?
  21. Save and Load .bat game
  22. How can I add greater than and less than into a batch file variable
  23. Batch file to delete files older than N hours or minutes
  24. Batch rename sequential files by padding with zeroes
  25. How to loop through comma separated string in batch?
  26. Windows Batch help in setting a variable from command output [duplicate]
  27. How to click a button using a batch file?
  28. Batch File To Play A Song
  29. To “Call” or “Not to Call” a batch file?
  30. Mapping a network drive without hardcoding a drive letter in a batch file

Leave a Comment