How to use FindWindow to find a visible or invisible window with a partial name in VBA

by

I found the following code in this vbforums.com answer and enhanced it to look for visible or invisible windows as well, therefore hopefully answering both your questions:

Option Explicit

Private Declare Function FindWindow Lib "User32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowText Lib "User32" Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function GetWindowTextLength Lib "User32" Alias "GetWindowTextLengthA" (ByVal hWnd As Long) As Long
Private Declare Function GetWindow Lib "User32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
Private Declare Function IsWindowVisible Lib "User32" (ByVal hWnd As Long) As Boolean

Private Const GW_HWNDNEXT = 2

Private Sub Test()

    Dim lhWndP As Long
    If GetHandleFromPartialCaption(lhWndP, "Excel") = True Then
        If IsWindowVisible(lhWndP) = True Then
          MsgBox "Found VISIBLE Window Handle: " & lhWndP, vbOKOnly + vbInformation
        Else
          MsgBox "Found INVISIBLE Window Handle: " & lhWndP, vbOKOnly + vbInformation
        End If
    Else
        MsgBox "Window 'Excel' not found!", vbOKOnly + vbExclamation
    End If

End Sub

Private Function GetHandleFromPartialCaption(ByRef lWnd As Long, ByVal sCaption As String) As Boolean

    Dim lhWndP As Long
    Dim sStr As String
    GetHandleFromPartialCaption = False
    lhWndP = FindWindow(vbNullString, vbNullString) 'PARENT WINDOW
    Do While lhWndP <> 0
        sStr = String(GetWindowTextLength(lhWndP) + 1, Chr$(0))
        GetWindowText lhWndP, sStr, Len(sStr)
        sStr = Left$(sStr, Len(sStr) - 1)
        If InStr(1, sStr, sCaption) > 0 Then
            GetHandleFromPartialCaption = True
            lWnd = lhWndP
            Exit Do
        End If
        lhWndP = GetWindow(lhWndP, GW_HWNDNEXT)
    Loop

End Function

The code searches for a window with a partial title of “Excel” and tells you if it found it and if it’s a visible window or not. You should be able to adapt it for your own purposes.

More Related Contents:

  1. Sequence of numbers based on start and end value of 2 cells [closed]
  2. Function to convert column number to letter?
  3. Better way to find last used row
  4. How to insert a picture into Excel at a specified cell position with VBA
  5. 2 Dimensional array from range [closed]
  6. Save multiple sheets to .pdf
  7. Having multiple Excel instances launched, how can I get the Application Object for all of them?
  8. How can I create a calendar input in VBA Excel?
  9. Using Google Chrome in Selenium VBA (Installation Steps)
  10. Dir() function not working in Mac Excel 2011 VBA
  11. Merge values of column B based on common values on column A
  12. How to use workbook.saveas with automatic Overwrite
  13. How to import a table from web page (with “div class”) to excel?
  14. Range limit conundrum
  15. How do you run a .exe with parameters using vba’s shell()?
  16. How to determine the last Row used in VBA including blank spaces in between [duplicate]
  17. Using VBA to detect which decimal sign the computer is using
  18. Referencing Excel Userform Control Name Value From String (VBA)
  19. Loop through each row of a range in Excel
  20. Fill formula down till last row in column
  21. Outputting Excel rows to a series of text files
  22. How to create a range from two ranges in VBA?
  23. XML parse VBA excel (function trip, & MSXML2.DOMDocument)
  24. If string contains word from list, return value adjacent to list value
  25. Refreshing all the pivot tables in my excel workbook with a macro
  26. excel vba freeze pane without select
  27. Converting a string representation of a constant into a constant?
  28. VBA WinHTTP to download file from password proteced https website
  29. Function Overloading and UDF in Excel VBA
  30. VBA Excel simple Error Handling

Leave a Comment