Match parenthesised block using regular expressions in vim

by

This is not possible with vim regular expressions (as language that allows such nested constructs is not regular), but is possible with ‘regular’ expressions provided by perl (as well as by other languages I do not know enough to be sure) and perl can be used from inside vim. I don’t like vim-perl bindings (because it is very limited), but if you know all cases that should work, then you could use recursion feature of perl regular expressions (requires newer perl, I have 5.12*):

perl VIM::Msg($+{"outer"}) if $curbuf->Get(3) =~ /someKeyword\((?'outer'(?'inner'"(?:\\.|[^"])*"|'(?:[^']|'')*'|[^()]*|\((?P>inner)*\))*)\)/

Note that if can avoid such regular expressions, you should do it (because you depend on re compiler too much), so I suggest to use vim motions directly:

let s:reply=""
function! SetReplyToKeywordArgs(...)
    let [sline, scol]=getpos("'[")[1:2]
    let [eline, ecol]=getpos("']")[1:2]
    let lchar=len(matchstr(getline(eline), '\%'.ecol.'c.'))
    if lchar>1
        let ecol+=lchar-1
    endif
    let text=[]
    let ellcol=col([eline, '$'])
    let slinestr=getline(sline)
    if sline==eline
        if ecol>=ellcol
            call extend(text, [slinestr[(scol-1):], ""])
        else
            call add(text, slinestr[(scol-1):(ecol-1)])
        endif
    else
        call add(text, slinestr[(scol-1):])
        let elinestr=getline(eline)
        if (eline-sline)>1
            call extend(text, getline(sline+1, eline-1))
        endif
        if ecol<ellcol
            call add(text, elinestr[:(ecol-1)])
        else
            call extend(text, [elinestr, ""])
        endif
    endif
    let s:reply=join(text, "\n")
endfunction
function! GetKeywordArgs()
    let winview=winsaveview()
    keepjumps call search('someKeyword', 'e')
    setlocal operatorfunc=SetReplyToKeywordArgs
    keepjumps normal! f(g@i(
    call winrestview(winview)
    return s:reply
endfunction

You can use something like

let savedureg=@"
let saved0reg=@0
keepjumps normal! f(yi(
let s:reply=@"
let @"=savedureg
let @0=saved0reg

instead of operatorfunc to save and restore registers, but the above code leaves all registers and marks untouched, what I can’t guarantee with saved* stuff. It also guarantees that if you remove join() around text, you will save information about the location of NULLs (if you care about them, of course). It is not possible with registers variant.

More Related Contents:

  1. How can I make my match non greedy in vim?
  2. Remove everything except regex match in Vim
  3. How does one escape backslashes and forward slashes in VIM find/search?
  4. How to search and replace with a counter-based expression in Vim?
  5. How to get Vim to highlight non-ascii characters?
  6. Why does VIM have its own regex syntax?
  7. Can I substitute multiple items in a single regular expression in VIM or Perl?
  8. Is it possible to escape regex metacharacters reliably with sed
  9. Regex: match everything but a specific pattern
  10. bash regex with quotes?
  11. Regular expression for duplicate words
  12. Regular expression to match any character being repeated more than 10 times
  13. Parsing scientific notation sensibly?
  14. Why is a character class faster than alternation?
  15. Regex: Remove lines containing “help”, etc
  16. Mail::RFC822::Address Regex
  17. Regular Expressions- Match Anything
  18. How to Use/Enable (RegExp object) Regular Expression using VBA (MACRO) in word
  19. Remove .php from urls with htaccess
  20. What is the Regular Expression For “Not Whitespace and Not a hyphen”
  21. replace a part of a string with REGEXP in sqlite3
  22. Split a string on whitespace in Go?
  23. how to use a regular expression to extract json fields?
  24. Regex for positive float numbers
  25. shell script. how to extract string using regular expressions
  26. Capturing text before and after a C-style code block with a Perl regular expression
  27. Regular expression to match a valid absolute Windows directory containing spaces
  28. Regular Expression for getting everything after last slash [duplicate]
  29. Regex: Get Filename Without Extension in One Shot?
  30. How does the ? make a quantifier lazy in regex

Leave a Comment