Can I substitute multiple items in a single regular expression in VIM or Perl?

by

You can do this in vim using a Dictionary:

:%s/quick\|lazy/\={'quick':'slow','lazy':'energetic'}[submatch(0)]/g

This will change the following text:

The quick brown fox ran quickly next to the lazy brook.

into:

The slow brown fox ran slowly next to the energetic brook.

To see how this works, see :help sub-replace-expression and :help Dictionary. In short,

  • \= lets you substitute in the result of a vim expression.
  • {'quick':'slow', 'lazy':'energetic'} is a vim dictionary (like a hash in perl or ruby, or an object in javascript) that uses [] for lookups.
  • submatch(0) is the matched string

This can come in handy when refactoring code – say you want to exchange the variable names for foo, bar, and baz changing

  • foo → bar
  • bar → baz
  • baz → foo

Using a sequence of %s/// commands would be tricky, unless you used temporary variable names – but you’d have to make sure those weren’t hitting anything else. Instead, you can use a Dictionary to do it in one pass:

:%s/\<\%(foo\|bar\|baz\)\>/\={'foo':'bar','bar':'baz','baz':'foo'}[submatch(0)]/g

Which changes this code

int foo = 0;
float bar = pow(2.0, (float) foo);
char baz[256] = {};

sprintf(baz,"2^%d = %f\n", foo, bar);

into:

int bar = 0;
float baz = pow(2.0, (float) bar);
char foo[256] = {};

sprintf(foo,"2^%d = %f\n", bar, baz);

If you find yourself doing this a lot, you may want to add the following to your ~/.vimrc:

" Refactor the given lines using a dictionary
" replacing all occurences of each key in the dictionary with its value
function! Refactor(dict) range
  execute a:firstline . ',' . a:lastline .  's/\C\<\%(' . join(keys(a:dict),'\|'). '\)\>/\='.string(a:dict).'[submatch(0)]/ge'
endfunction

command! -range=% -nargs=1 Refactor :<line1>,<line2>call Refactor(<args>)

This lets you use the :Refactor {'frog':'duck', 'duck':'frog'} command, and is slightly
less repetitive than creating the regex for the dict manually.

More Related Contents:

  1. string pattern matching using perl regex [closed]
  2. Awk – replace coumn 2 in table 1 from coumn 2 in table 2 based on matching data in column 1 (common between tables)
  3. The recognizing power of “modern” regexes
  4. Should I use \d or [0-9] to match digits in a Perl regex?
  5. Escaping a forward slash in a regular expression
  6. How can I use a variable in the replacement side of the Perl substitution operator?
  7. When is \G useful application in a regex?
  8. Using alternation or character class for single character matching?
  9. Verbs that act after backtracking and failure
  10. regex to match word boundary beginning with special characters
  11. Does the ‘o’ modifier for Perl regular expressions still provide any benefit?
  12. How do I handle special characters in a Perl regex?
  13. Remove everything except regex match in Vim
  14. How can I exclude some characters from a class?
  15. Can I use Perl regular expressions to match balanced text?
  16. What is the difference between \1 and $1 in a Perl regex?
  17. How does one escape backslashes and forward slashes in VIM find/search?
  18. How do I perform a Perl substitution on a string while keeping the original?
  19. How can I match a quote-delimited string with a regex?
  20. How can I use a variable for a regex pattern without interpreting meta characters?
  21. How can I parse quoted CSV in Perl with a regex?
  22. How to get Vim to highlight non-ascii characters?
  23. how to match a number which is less than or equal to 100?
  24. How can I match double-quoted strings with escaped double-quote characters?
  25. How to escape dollar sign ($) in a string using perl regex
  26. How do I search and replace across multiple lines with Perl?
  27. Match parenthesised block using regular expressions in vim
  28. How to use different separators (/ , |) in a regular expression
  29. Counting number of occurrences of a string inside another (Perl)
  30. How to replace a string in an existing file in Perl

Leave a Comment