Matlab: How to bend line in image

by

Ok, here is a way involving several randomization steps needed to get a “natural” non symmetrical appearance.

I am posting the actual code in Mathematica, just in case someone cares translating it to Matlab. 

(* A preparatory step: get your image and clean it*)
i = Import@"http://i.stack.imgur.com/YENhB.png";
i1 = Image@Replace[ImageData[i], {0., 0., 0.} -> {1, 1, 1}, {2}];
i2 = ImageSubtract[i1, i];
i3 = Inpaint[i, i2]

enter image description here

(*Now reduce to a skeleton to get a somewhat random starting point.  
The actual algorithm for this dilation does not matter, as far as we 
get a random area slightly larger than the original elipses *)
id = Dilation[SkeletonTransform[
             Dilation[SkeletonTransform@ColorNegate@Binarize@i3, 3]], 1]

enter image description here

(*Now the real random dilation loop*)
(*Init vars*)
p = Array[1 &, 70]; j = 1;
(*Store in w an image with a different color for each cluster, so we 
can find edges between them*)
w = (w1 = 
      WatershedComponents[
       GradientFilter[Binarize[id, .1], 1]]) /. {4 -> 0} // Colorize;
(*and loop ...*)
For[i = 1, i < 70, i++,
 (*Select edges in w and dilate them with a random 3x3 kernel*)
 ed = Dilation[EdgeDetect[w, 1], RandomInteger[{0, 1}, {3, 3}]];
 (*The following is the core*)
 p[[j++]] = w =
   ImageFilter[  (* We apply a filter to the edges*)
    (Switch[
          Length[#1],  (*Count the colors in a 3x3 neighborhood of each pixel*)
          0, {{{0, 0, 0}, 0}},          (*If no colors, return bkg*)
          1, #1,                        (*If one color, return it*)
          _, {{{0, 0, 0}, 0}}])[[1, 1]] (*If more than one color, return bkg*)&@
      Cases[Tally[Flatten[#1, 1]], 
       Except[{{0.`, 0.`, 0.`}, _}]] & (*But Don't count bkg pixels*),
    w, 1,
    Masking -> ed,       (*apply only to edges*)
    Interleaving -> True (*apply to all color chanels at once*)]
 ]

The result is:

enter image description here

Edit

For the Mathematica oriented reader, a functional code for the last loop could be easier (and shorter):

NestList[
 ImageFilter[  
   If[Length[#1] ==  1, #1[[1, 1]], {0, 0, 0}] &@
     Cases[Tally[Flatten[#1, 1]], Except[{0.` {1, 1, 1}, _}]] & , #, 1,
   Masking      -> Dilation[EdgeDetect[#, 1], RandomInteger[{0, 1}, {3, 3}]],  
   Interleaving -> True ] &,
 WatershedComponents@GradientFilter[Binarize[id,.1],1]/.{4-> 0}//Colorize, 
5]

More Related Contents:

  1. To remove blood vessel [closed]
  2. how to get a single feature vector from SIFT descriptor [closed]
  3. How can I convert an RGB image to grayscale but keep one color?
  4. How to make the blackboard text appear clearer using MATLAB?
  5. Image rotation by Matlab without using imrotate
  6. Nearest-neighbor interpolation algorithm in MATLAB
  7. character reconstruction and filling for OCR
  8. How to divide an image into blocks in MATLAB?
  9. resizing 3D matrix (image) in MATLAB
  10. Align already captured rgb and depth images
  11. Is there a substitute for blockproc in Matlab?
  12. Matlab Template Matching Using FFT
  13. MATLAB: Drawing a line over a black and white image
  14. Explanation of the Histogram Equalization function in MATLAB [closed]
  15. How do I edit the axes of an image in MATLAB to reverse the direction?
  16. imresize – trying to understand the bicubic interpolation
  17. Loading multiple images in MATLAB
  18. Matlab imshow omit NaN
  19. Content-Based Image Retrieval and Precision-Recall graphs using Color Histograms in MATLAB
  20. How to change an image from Cartesian to Polar coordinates in Matlab?
  21. Fitting largest circle in free area in image with distributed particle
  22. How to draw a line on an image in matlab?
  23. Select largest object in an image
  24. How to generate all pairs from two vectors in MATLAB using vectorised code?
  25. Octave / Matlab: Extend a vector making it repeat itself?
  26. How should I update the data of a plot in Matlab?
  27. Automatically plot different colored lines
  28. Example of 10-fold SVM classification in MATLAB
  29. How to draw horizontal and vertical lines in MATLAB?
  30. Plotting data on time (date) axis

Leave a Comment