Prolog removing unique elements only

by

Prolog rules are read independently of each other, so you need one rule for the case where the element is unique and one where it is not. Provided the order of the elements is not relevant, you might use:

?- remUniqueVals([A,B,C], [1,1]).
A = B, B = 1,
dif(C, 1) ;
A = C, C = 1,
dif(B, 1),
dif(B, 1) ;
B = C, C = 1,
dif(A, 1),
dif(A, 1) ;
false.

?- remUniqueVals([1,1,2,2,3,4,4,5,6,6,6],Q).
Q = [1, 1, 2, 2, 4, 4, 6, 6, 6] ;
false.

remUniqueVals([], []).
remUniqueVals([Q1|RestQ],[Q1|Xs0]) :-
   memberd(Q1, RestQ),
   phrase(delall(Q1, RestQ, NewQ), Xs0, Xs),
   remUniqueVals(NewQ, Xs).
remUniqueVals([Q1|RestQ],Xs) :-
   maplist(dif(Q1), RestQ),
   remUniqueVals(RestQ,Xs).

memberd(X, [X|_Xs]).
memberd(X, [Y|Xs]) :-
   dif(X,Y),
   memberd(X, Xs).

delall(_X, [], []) --> [].
delall(X, [X|Xs], Ys) -->
   [X],
   delall(X, Xs, Ys).
delall(X, [Y|Xs], [Y|Ys]) -->
   {dif(X,Y)},
   delall(X, Xs, Ys).

Here is an alternate definition for memberd/2 which might be more efficient using if_/3:

memberd(E, [X|Xs]) :-
   if_(E = X, true, memberd(E, Xs) ).

More Related Contents:

  1. prolog change show answer to print into list
  2. Prolog union for A U B U C
  3. Prolog – count repetitions in list
  4. Find powers of 2 in a list Prolog
  5. Flatten a list in Prolog
  6. How do I append lists in Prolog?
  7. Prolog: Filtering a list?
  8. Remove duplicates in list (Prolog)
  9. Subsets in Prolog
  10. Get elements from list of lists
  11. Lazy lists in Prolog?
  12. Segregating Lists in Prolog
  13. Splitting a list of integers into a list of positive integers and a list of negative integers
  14. How to count number of element occurrences in a list in Prolog
  15. Intersection and union of 2 lists
  16. Prolog: First duplicate value
  17. Implementing “last” in Prolog
  18. Recursive Prolog predicate for reverse / palindrome
  19. Prolog, find minimum in a list
  20. What is Haskell’s Stream Fusion
  21. Using return vs. not using return in the list monad
  22. Cartesian product of infinite lists in Haskell
  23. Hide Show content-list with only CSS, no javascript used
  24. Recombining a list of Data.frames into a single data frame [duplicate]
  25. What is the most efficient way to cast a list as a data frame?
  26. “bad words” filter [closed]
  27. Python: create a pandas data frame from a list
  28. Merging two lists in Haskell
  29. Erlang lists with single numbers over 8?
  30. Grouping a list into lists of n elements in Haskell

Leave a Comment