Prolog, find minimum in a list

by

It is common to use a so-called “lagged argument” to benefit from first-argument indexing:

list_min([L|Ls], Min) :-
    list_min(Ls, L, Min).

list_min([], Min, Min).
list_min([L|Ls], Min0, Min) :-
    Min1 is min(L, Min0),
    list_min(Ls, Min1, Min).

This pattern is called a fold (from the left), and foldl/4, which is available in recent SWI versions, lets you write this as:

list_min([L|Ls], Min) :- foldl(num_num_min, Ls, L, Min).

num_num_min(X, Y, Min) :- Min is min(X, Y).

Notice though that this cannot be used in all directions, for example:

?- list_min([A,B], 5).
is/2: Arguments are not sufficiently instantiated

If you are reasoning about integers, as seems to be the case in your example, I therefore recommend you use CLP(FD) constraints to naturally generalize the predicate. Instead of (is)/2, simply use (#=)/2 and benefit from a more declarative solution:

:- use_module(library(clpfd)).

list_min([L|Ls], Min) :- foldl(num_num_min, Ls, L, Min).

num_num_min(X, Y, Min) :- Min #= min(X, Y).

This can be used as a true relation which works in all directions, for example:

?- list_min([A,B], 5).

yielding:

A in 5..sup,
5#=min(B, A),
B in 5..sup.

More Related Contents:

  1. prolog change show answer to print into list
  2. Prolog union for A U B U C
  3. Prolog – count repetitions in list
  4. Prolog removing unique elements only
  5. Find powers of 2 in a list Prolog
  6. Flatten a list in Prolog
  7. How do I append lists in Prolog?
  8. Prolog: Filtering a list?
  9. Remove duplicates in list (Prolog)
  10. Subsets in Prolog
  11. Get elements from list of lists
  12. Lazy lists in Prolog?
  13. Segregating Lists in Prolog
  14. Splitting a list of integers into a list of positive integers and a list of negative integers
  15. How to count number of element occurrences in a list in Prolog
  16. Intersection and union of 2 lists
  17. Prolog: First duplicate value
  18. Implementing “last” in Prolog
  19. Recursive Prolog predicate for reverse / palindrome
  20. Haskell finding mean of cubes of odd members Any ideas? [closed]
  21. How to check a list contains substring from other list using scala?
  22. Elixir lists interpreted as char lists
  23. How to flatten a list to a list without coercion?
  24. Decrementing ranges in Haskell
  25. Zip with default value instead of dropping values?
  26. Replace individual list elements in Haskell?
  27. In Dart, what’s the difference between List.from and .of, and between Map.from and .of?
  28. Prevent unlist to drop NULL values
  29. Pythonic way to convert a list of integers into a string of comma-separated ranges
  30. Slicing a list into a list of sub-lists [duplicate]

Leave a Comment