Return Index of an Element in an Array Excel VBA

by 
Dim pos, arr, val

arr=Array(1,2,4,5)
val = 4

pos=Application.Match(val, arr, False)

if not iserror(pos) then
   Msgbox val & " is at position " & pos
else
   Msgbox val & " not found!"
end if

Updated to show using Match (with .Index) to find a value in a dimension of a two-dimensional array:

Dim arr(1 To 10, 1 To 2)
Dim x

For x = 1 To 10
    arr(x, 1) = x
    arr(x, 2) = 11 - x
Next x

Debug.Print Application.Match(3, Application.Index(arr, 0, 1), 0)
Debug.Print Application.Match(3, Application.Index(arr, 0, 2), 0)

EDIT: it’s worth illustrating here what @ARich pointed out in the comments – that using Index() to slice an array has horrible performance if you’re doing it in a loop.

In testing (code below) the Index() approach is almost 2000-fold slower than using a nested loop.

Sub PerfTest()

    Const VAL_TO_FIND As String = "R1800:C8"
    Dim a(1 To 2000, 1 To 10)
    Dim r As Long, c As Long, t

    For r = 1 To 2000
        For c = 1 To 10
            a(r, c) = "R" & r & ":C" & c
        Next c
    Next r

    t = Timer
    Debug.Print FindLoop(a, VAL_TO_FIND), Timer - t
    ' >> 0.00781 sec

     t = Timer
    Debug.Print FindIndex(a, VAL_TO_FIND), Timer - t
    ' >> 14.18 sec

End Sub

Function FindLoop(arr, val) As Boolean
    Dim r As Long, c As Long
    For r = 1 To UBound(arr, 1)
    For c = 1 To UBound(arr, 2)
        If arr(r, c) = val Then
            FindLoop = True
            Exit Function
        End If
    Next c
    Next r
End Function

Function FindIndex(arr, val)
    Dim r As Long
    For r = 1 To UBound(arr, 1)
        If Not IsError(Application.Match(val, Application.Index(arr, r, 0), 0)) Then
            FindIndex = True
            Exit Function
        End If
    Next r
End Function

More Related Contents:

  1. Excel-VBA – Insert new first column in datafield array without loops or API calls
  2. Creating an Array from a Range in VBA
  3. Expanding column cells for each column cell
  4. How do I slice an array in Excel VBA?
  5. Check if a value is in an array or not with Excel VBA
  6. Matching values in string array
  7. Deleting Elements in an Array if Element is a Certain value VBA
  8. Is it possible to fill an array with row numbers which match a certain criteria without looping?
  9. Can Excel’s INDEX function return array?
  10. How to automatically input an array formula as string with more than 255 characters in length into an excel cell using VBA?
  11. Writing an array to a range. Only getting first value of array
  12. Excel VBA: Range to String Array in 1 step
  13. Faster way of using Sumifs()
  14. How to initialize a multidimensional array variable in vba for excel
  15. VBA using ubound on a multidimensional array
  16. Turn Excel range into VBA string
  17. Get values from union of non-contiguous ranges into array with VBA with a simple command (no loops)
  18. Why am I having issues assigning a Range to an Array of Variants
  19. Subscript out of range error with an array – no idea why?
  20. VBA Excel large data manipulation taking forever
  21. Performance difference between looping range vs looping array
  22. Create Chart from Array data and not range
  23. Excel VBA Quickest way to sort an array of numbers in descending order?
  24. Simple VBA array join not working
  25. Excel VBA – How to Redim a 2D array?
  26. ReDim Preserve “Subscript Out of Range”
  27. Sorting a multidimensionnal array in VBA
  28. Why array indexes are zero based in most programming languages?
  29. Dynamically Dimensioning A VBA Array?
  30. VBA – Returning array from Property Get

Leave a Comment