Save attachments to a folder and rename them

by

This is my Save Attachments script. You select all the messages that you want the attachments saved from, and it will save a copy there. It also adds text to the message body indicating where the attachment is saved. You could easily change the folder name to include the date, but you would need to make sure the folder existed before starting to save files.

Public Sub SaveAttachments()
Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Get the path to your My Documents folder
strFolderpath = CreateObject("WScript.Shell").SpecialFolders(16)
On Error Resume Next

' Instantiate an Outlook Application object.
Set objOL = CreateObject("Outlook.Application")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Set the Attachment folder.
strFolderpath = strFolderpath & "\Attachments\"

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

    ' This code only strips attachments from mail items.
    ' If objMsg.class=olMail Then
    ' Get the Attachments collection of the item.
    Set objAttachments = objMsg.Attachments
    lngCount = objAttachments.Count
    strDeletedFiles = ""

    If lngCount > 0 Then

        ' We need to use a count down loop for removing items
        ' from a collection. Otherwise, the loop counter gets
        ' confused and only every other item is removed.

        For i = lngCount To 1 Step -1

            ' Save attachment before deleting from item.
            ' Get the file name.
            strFile = objAttachments.Item(i).FileName

            ' Combine with the path to the Temp folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

            ' Delete the attachment.
            objAttachments.Item(i).Delete

            'write the save as path to a string to add to the message
            'check for html and use html tags in link
            If objMsg.BodyFormat <> olFormatHTML Then
                strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
            Else
                strDeletedFiles = strDeletedFiles & "<br>" & "<a href="https://stackoverflow.com/questions/15531093/file://" & _
                strFile & "">" & strFile & "</a>"
            End If

            'Use the MsgBox command to troubleshoot. Remove it from the final code.
            'MsgBox strDeletedFiles

        Next i

        ' Adds the filename string to the message body and save it
        ' Check for HTML body
        If objMsg.BodyFormat <> olFormatHTML Then
            objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
        Else
            objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
        End If
        objMsg.Save
    End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
End Sub

More Related Contents:

  1. Get reference to additional Inbox
  2. How to add default signature in Outlook
  3. How do I trigger a macro to run after a new mail is received in Outlook?
  4. Outlook VBA – Run a code every half an hour
  5. For Each loop: Some items get skipped when looping through Outlook mailbox to delete items
  6. Can I iterate through all Outlook emails in a folder including sub-folders?
  7. Download attachment from Outlook and Open in Excel
  8. Embed picture in outlook mail body excel vba
  9. How to move each emails from inbox to a sub-folder [duplicate]
  10. Outlook Reply or ReplyAll to an Email
  11. VBA Search in Outlook
  12. How to do late binding in VBA?
  13. Check for the senderEmailAddress
  14. Removing a string that includes CRLF characters from body of e-mail
  15. How to insert text into Outlook email editor using VBA
  16. How do you extract email addresses from the ‘To’ field in outlook?
  17. How do I open an outlook .msg file from my harddrive that is NOT in outlook?
  18. Add a “CC recipient” to Outlook 2010 VBA
  19. Using visual basic to access subfolder in Inbox?
  20. When is a MailItem not a MailItem? [closed]
  21. Search structured text in Outlook body
  22. Switching the FROM Inbox
  23. How to add an embedded image to an HTML message in Outlook 2010
  24. Iterate all email items in a specific Outlook folder
  25. Restrict Outlook Items by Date
  26. VBA Outlook Mail .display, recording when/if sent manually
  27. Where does Outlook store the VBA code files?
  28. Working with current open email
  29. Debugging an Outlook 2007 script fired by a rule
  30. Runtime error 287. Sending Emails through Outlook using VBA in Access

Leave a Comment