Outlook VBA – Run a code every half an hour

by

http://www.outlookcode.com/threads.aspx?forumid=2&messageid=7964

Place the following code in the ThisOutlookSession module (Tools->Macros->VB Editor):

Private Sub Application_Quit()
  If TimerID <> 0 Then Call DeactivateTimer 'Turn off timer upon quitting **VERY IMPORTANT**
End Sub

Private Sub Application_Startup()
  MsgBox "Activating the Timer."
  Call ActivateTimer(1) 'Set timer to go off every 1 minute
End Sub

Place the following code in an new VBA module

Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerfunc As Long) As Long
Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long

Public TimerID As Long 'Need a timer ID to eventually turn off the timer. If the timer ID <> 0 then the timer is running

Public Sub ActivateTimer(ByVal nMinutes As Long)
  nMinutes = nMinutes * 1000 * 60 'The SetTimer call accepts milliseconds, so convert to minutes
  If TimerID <> 0 Then Call DeactivateTimer 'Check to see if timer is running before call to SetTimer
  TimerID = SetTimer(0, 0, nMinutes, AddressOf TriggerTimer)
  If TimerID = 0 Then
    MsgBox "The timer failed to activate."
  End If
End Sub

Public Sub DeactivateTimer()
Dim lSuccess As Long
  lSuccess = KillTimer(0, TimerID)
  If lSuccess = 0 Then
    MsgBox "The timer failed to deactivate."
  Else
    TimerID = 0
  End If
End Sub

Public Sub TriggerTimer(ByVal hwnd As Long, ByVal uMsg As Long, ByVal idevent As Long, ByVal Systime As Long)
  MsgBox "The TriggerTimer function has been automatically called!"
End Sub

Key points:

1) This timer function does not require that a particular window is open; it works in the background

2) If you don’t deactivate the timer when the application closes it will likely crash

3) The example shows the timer being activated at startup, but it can just as easily be called by a different event

4) If you don’t see the msgbox indicating that the timer was activated upon startup, your macro security is set too high

5) To have the timer deactivate after one iteration of the time interval add: If TimerID <> 0 Then Call DeactivateTimer after the msgbox statement in sub TriggerTimer

Someone else suggested

“one point to note, if you don’t check if TimerID is the same as idevent in the TriggerTimer, you get every so often, and not the time you asked for.”

Public Sub TriggerTimer(ByVal hwnd As Long, ByVal uMsg As Long, ByVal idevent As Long, ByVal Systime As Long)
    'keeps calling every X Minutes unless deactivated
    If idevent = TimerID Then
        MsgBox "The TriggerTimer function has been automatically called!"
    End If
End Sub

More Related Contents:

  1. Get reference to additional Inbox
  2. How to add default signature in Outlook
  3. How do I trigger a macro to run after a new mail is received in Outlook?
  4. For Each loop: Some items get skipped when looping through Outlook mailbox to delete items
  5. Can I iterate through all Outlook emails in a folder including sub-folders?
  6. Download attachment from Outlook and Open in Excel
  7. Embed picture in outlook mail body excel vba
  8. How to move each emails from inbox to a sub-folder [duplicate]
  9. Save attachments to a folder and rename them
  10. Outlook Reply or ReplyAll to an Email
  11. VBA Search in Outlook
  12. How to do late binding in VBA?
  13. Distinguish visible and invisible attachments with Outlook VBA
  14. Check for the senderEmailAddress
  15. Removing a string that includes CRLF characters from body of e-mail
  16. How to insert text into Outlook email editor using VBA
  17. How do you extract email addresses from the ‘To’ field in outlook?
  18. How do I open an outlook .msg file from my harddrive that is NOT in outlook?
  19. Using visual basic to access subfolder in Inbox?
  20. When is a MailItem not a MailItem? [closed]
  21. Search structured text in Outlook body
  22. Switching the FROM Inbox
  23. How to add an embedded image to an HTML message in Outlook 2010
  24. Iterate all email items in a specific Outlook folder
  25. Restrict Outlook Items by Date
  26. MS Access VBA: Sending an email through Outlook [closed]
  27. Where does Outlook store the VBA code files?
  28. Working with current open email
  29. Debugging an Outlook 2007 script fired by a rule
  30. Runtime error 287. Sending Emails through Outlook using VBA in Access

Leave a Comment