Delete vowels in a list

by

The following is based on the reification of term equality/inequality.

First, we first define list_memberd_t/3, which behaves just like the memberd_truth/3 but has a different argument order:

list_memberd_t([]    ,_,false).
list_memberd_t([Y|Ys],X,Truth) :-
   if_(X=Y, Truth=true, list_memberd_t(Ys,X,Truth)).

list_memberd_truth(Xs,X,Truth) :- list_memberd_t(Xs,X,Truth).

For the sake of brevity, let’s define memberd_t/3 based on list_memberd_t/3:

memberd_t(X,Xs,Truth) :- list_memberd_t(Xs,X,Truth).

As a parallel to library(apply), let’s define tinclude/3:

:- meta_predicate tinclude(2,?,?).
tinclude(P_2,Xs,Zs) :- 
    list_tinclude_list(Xs,P_2,Zs).

list_tinclude_list([],   _P_2,[]).
list_tinclude_list([E|Es],P_2,Fs0) :-
    if_(call(P_2,E), Fs0 = [E|Fs], Fs0 = Fs),
    list_tinclude_list(Es,P_2,Fs).

tfilter/3 is another name for tinclude/3:

tfilter(P_2,As,Bs) :-
   tinclude(P_2,As,Bs).

Next, we define the meta-predicate texclude/3, the opposite of tinclude/3:

:- meta_predicate texclude(2,?,?).
texclude(P_2,Xs,Zs) :- 
    list_texclude_list(Xs,P_2,Zs).

list_texclude_list([],_,[]).
list_texclude_list([E|Es],P_2,Fs0) :-
    if_(call(P_2,E), Fs0 = Fs, Fs0 = [E|Fs]),
    list_texclude_list(Es,P_2,Fs).

Now let’s use them together!

?- texclude(list_memberd_truth([a,e,i,o,u]),
            [d,e,l,e,t,e,' ',v,o,w,e,l,s,' ',i,n,' ',a,' ',l,i,s,t], Filtered).
Filtered  = [d,  l,  t,  ' ',v,  w,  l,s,' ',  n,' ',  ' ',l,  s,t].

Edit

As an alternative to using above texclude/3, let’s use tinclude/3 with an auxiliary predicate not/3 to flip the truth value:

:- meta_predicate not(2,?,?).
not(P_2,X,Truth) :-
   call(P_2,X,Truth0),
   truth_flipped(Truth0,Truth).

truth_flipped(true,false).
truth_flipped(false,true).

Sample query:

?- tinclude(not(list_memberd_truth([a,e,i,o,u])),
            [d,e,l,e,t,e,' ',v,o,w,e,l,s,' ',i,n,' ',a,' ',l,i,s,t], Filtered).
Filtered  = [d,  l,  t,  ' ',v,  w,  l,s,' ',  n,' ',  ' ',l,  s,t].

More Related Contents:

  1. Prolog map procedure that applies predicate to list elements
  2. What is the difference between ‘ and ” in Prolog?
  3. Definition of a path/trail/walk
  4. Definition of Reflexive Transitive Closure
  5. Most general higher-order constraint describing a sequence of integers ordered with respect to a relation
  6. Reification of term equality/inequality
  7. Finding Unique Items in a List
  8. Prolog: a person is a sibling of himself?
  9. What is the logical ‘not’ in Prolog?
  10. Stack overflow in Prolog DCG grammar rule: how to handle large lists efficiently or lazily
  11. Using a constrained variable with `length/2`
  12. Safer type tests in Prolog
  13. Complexity of ISO Prolog predicates
  14. Explanation of a Prolog algorithm to append two lists together
  15. list of the values in the leaf nodes of binary tree T
  16. Meaning of instantiation mode indicators in arguments of Prolog predicates
  17. reversible “binary to number” predicate
  18. Collect all “minimum” solutions from a predicate
  19. Using \==/2 or dif/2
  20. Knowing when to use cut in prolog
  21. Good beginners material on Prolog [closed]
  22. ‘if’ in prolog?
  23. Should I avoid tail recursion in Prolog and in general?
  24. Prolog append with cut operator
  25. Understanding Difference Lists
  26. Define graph in Prolog: edge and path, finding if there is a path between two vertices
  27. Can you write between/3 in pure prolog?
  28. PROLOG: Determining if elements in list are equal if order does not matter
  29. Features of good Prolog code? [closed]
  30. GNU Prolog assert error

Leave a Comment