Definition of a path/trail/walk

by

How about defining path/4 like this?

path(R_2, Xs, A,Z) :-                   % A path `Xs` from `A` to `Z` is ...
   walk(R_2, Xs, A,Z),                  % ... a walk `Xs` from `A` to `Z` ...
   all_dif(Xs).                         % ... with no duplicates in `Xs`.

To aid universal termination, we swap the two goals in above conjunction …

path(R_2, Xs, A,Z) :-
   all_dif(Xs),                         % enforce disequality ASAP
   walk(R_2, Xs, A,Z).

… and use the following lazy implementation of all_dif/1: 

all_dif(Xs) :-                          % enforce pairwise term inequality
   freeze(Xs, all_dif_aux(Xs,[])).      % (may be delayed)

all_dif_aux([], _).
all_dif_aux([E|Es], Vs) :-               
   maplist(dif(E), Vs),                 % is never delayed
   freeze(Es, all_dif_aux(Es,[E|Vs])).  % (may be delayed)

walk/4 is defined like path/4 and path/5 given by the OP:

:- meta_predicate walk(2, ?, ?, ?).
walk(R_2, [X0|Xs], X0,X) :-
   walk_from_to_step(Xs, X0,X, R_2).

:- meta_predicate walk_from_to_step(?, ?, ?, 2).
walk_from_to_step([], X,X, _).
walk_from_to_step([X1|Xs], X0,X, R_2) :-
   call(R_2, X0,X1),
   walk_from_to_step(Xs, X1,X, R_2).

IMO above path/4 is simpler and more approachable, particularly for novices. Would you concur?

More Related Contents:

  1. Definition of Reflexive Transitive Closure
  2. Define graph in Prolog: edge and path, finding if there is a path between two vertices
  3. Prolog map procedure that applies predicate to list elements
  4. Most general higher-order constraint describing a sequence of integers ordered with respect to a relation
  5. Collect all “minimum” solutions from a predicate
  6. Delete vowels in a list
  7. Reification of term equality/inequality
  8. Prolog successor notation yields incomplete result and infinite loop
  9. Finding Unique Items in a List
  10. Prolog: a person is a sibling of himself?
  11. What is the logical ‘not’ in Prolog?
  12. Stack overflow in Prolog DCG grammar rule: how to handle large lists efficiently or lazily
  13. Using a constrained variable with `length/2`
  14. Einsteins Riddle Prolog
  15. Safer type tests in Prolog
  16. Complexity of ISO Prolog predicates
  17. Explanation of a Prolog algorithm to append two lists together
  18. list of the values in the leaf nodes of binary tree T
  19. Shuffle in prolog
  20. reversible “binary to number” predicate
  21. Using \==/2 or dif/2
  22. Converting Terms to Atoms preserving variable names in YAP prolog
  23. Good beginners material on Prolog [closed]
  24. ‘if’ in prolog?
  25. Prolog append with cut operator
  26. Understanding Difference Lists
  27. Can you write between/3 in pure prolog?
  28. PROLOG: Determining if elements in list are equal if order does not matter
  29. Features of good Prolog code? [closed]
  30. GNU Prolog assert error

Leave a Comment