Distinguish visible and invisible attachments with Outlook VBA

by

As I can test so far, an embedded attachment always have a MIME content ID, regardless whether it appears in the mail body. So the solution is to check whether it has a content ID.

Here is an example code that counts the visible attachments:

Sub ShowVisibleAttachmentCount()
    Const PR_ATTACH_CONTENT_ID As String = "http://schemas.microsoft.com/mapi/proptag/0x3712001F"
    Const PR_ATTACHMENT_HIDDEN As String = "http://schemas.microsoft.com/mapi/proptag/0x7FFE000B"

    Dim m As MailItem
    Dim a As Attachment
    Dim pa As PropertyAccessor
    Dim c As Integer
    Dim cid as String

    Dim body As String

    c = 0

    Set m = Application.ActiveInspector.CurrentItem
    body = m.HTMLBody

    For Each a In m.Attachments
        Set pa = a.PropertyAccessor
        cid = pa.GetProperty(PR_ATTACH_CONTENT_ID)

        If Len(cid) > 0 Then
            If InStr(body, cid) Then
            Else
                'In case that PR_ATTACHMENT_HIDDEN does not exists, 
                'an error will occur. We simply ignore this error and
                'treat it as false.
                On Error Resume Next
                If Not pa.GetProperty(PR_ATTACHMENT_HIDDEN) Then
                    c = c + 1
                End If
                On Error GoTo 0
            End If
        Else
            c = c + 1
        End If
    Next a
    MsgBox c
End Sub

When I run through all my outlook emails it gives the same number of attachments in the line.

UPDATE

Thanks to Dmitry Streblechenko’s information, I tested Outlook with email generated by Java Email library. The result shows that when an email attachment contains an CID but not appear in the email body, it will appear in the attachments line.

UPDATE

It looks there are still some cases that this is not good enough.
I have generated the following MIME email body:

Message-ID: <1044564324.2.1360638429705.JavaMail.joe@xxxx>
Subject: Test
MIME-Version: 1.0
Content-Type: multipart/alternative; 
    boundary="----=_Part_0_1327112367.1360638429515"
Return-Path: [email protected]
X-OriginalArrivalTime: 12 Feb 2013 03:07:16.0096 (UTC) FILETIME=[0FC1B000:01CE08CE]

------=_Part_0_1327112367.1360638429515
Content-Type: text/plain; charset=us-ascii
Content-Transfer-Encoding: 7bit

TTT
------=_Part_0_1327112367.1360638429515
Content-Type: multipart/related; 
    boundary="----=_Part_1_1747887937.1360638429520"

------=_Part_1_1747887937.1360638429520
Content-Type: text/html; charset=UTF-8
Content-Transfer-Encoding: quoted-printable

<html><head><meta http-equiv=3D'content-type' content=3D'text/html; charset=
=3DUTF-8'></head><title>TTT</title><body><img src=3D"cid:test1.png" alt=3D'=
=E6=81=AD=E8=B4=BA=E6=96=B0=E7=A6=A7' /><p>txt</p></body></html>
------=_Part_1_1747887937.1360638429520
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-ID: <test.png>

iVBORw0KGgoAAAANSUhEUgAAAIIAAAAmCAYAAAAIjkMFAAABHUlEQVR42u3Z0Q7CIAyFYd//pafx
ckFoS9ELvz8aE9mQrIfTFh8PAAAAAPgp1+t1vT9i32fm6FzP6JrKb3aulRAGARm9Z9dUAhWZY7Wm
7Hr+IvhdD+s+PhLCLNBZQZ12HI7QlBqyQohctxM8bvAFIcx2eEYIo/vuY5WAi3BzWlhZ+if7zs7T
UWtE10Asgd3bUSxWHvrMobJOtXITQkjk5Z3gdaWaqBBWouYIhdy+E+TsPNHU0CUEbjDJ49GxE0KI
nBNUheAcYbPVy9QNmRaxUvVHd7Idf0gU2QDOduVqnkinoEb4QY1Q3V2RNrMqpB0h6BqKh0gZIWT/
AzjVycwcjSMcPI3buSebZiptaLbIBQAAAAAAAAAAAAAAAP6OJyO5jJ4bZa/gAAAAAElFTkSuQmCC

------=_Part_1_1747887937.1360638429520--

------=_Part_0_1327112367.1360638429515--

Notice that I have changed the referencing image content id in the body, and the actual image have a wrong content ID (so it is not referenced). However the image is not in the main part of the email (it is in a branch of an alternative part). That makes it invisible in outlook.

So to detect we have to make sure the attachment appears in the main MIME part… Looking for ways to do so.

UPDATE

Further digging I reaches this link and I added one more test – the PR_ATTACHMENT_HIDDEN property.

Also it is worth to say that outlook 2010 itself is not consistent. I have observed that sometimes the email list shows the attachment icon to indicate existence of attachments but there are nothing appear when opening it in an inspector.

References:

Sending Outlook Email with embedded image using VBS

MSDN – Attachment Properties

Forum – Identifying inline attachments

More Related Contents:

  1. Download attachment from Outlook and Open in Excel
  2. Get reference to additional Inbox
  3. How to add default signature in Outlook
  4. Outlook VBA – Run a code every half an hour
  5. For Each loop: Some items get skipped when looping through Outlook mailbox to delete items
  6. Can I iterate through all Outlook emails in a folder including sub-folders?
  7. Embed picture in outlook mail body excel vba
  8. How to move each emails from inbox to a sub-folder [duplicate]
  9. Save attachments to a folder and rename them
  10. Outlook Reply or ReplyAll to an Email
  11. VBA Search in Outlook
  12. How to do late binding in VBA?
  13. Check for the senderEmailAddress
  14. Removing a string that includes CRLF characters from body of e-mail
  15. How to insert text into Outlook email editor using VBA
  16. How do you extract email addresses from the ‘To’ field in outlook?
  17. How do I open an outlook .msg file from my harddrive that is NOT in outlook?
  18. Using visual basic to access subfolder in Inbox?
  19. When is a MailItem not a MailItem? [closed]
  20. Search structured text in Outlook body
  21. Switching the FROM Inbox
  22. How to add an embedded image to an HTML message in Outlook 2010
  23. Iterate all email items in a specific Outlook folder
  24. Restrict Outlook Items by Date
  25. VBA Outlook Mail .display, recording when/if sent manually
  26. MS Access VBA: Sending an email through Outlook [closed]
  27. Where does Outlook store the VBA code files?
  28. Working with current open email
  29. Debugging an Outlook 2007 script fired by a rule
  30. Runtime error 287. Sending Emails through Outlook using VBA in Access

Leave a Comment