How do I make a log of all ECHO commands in a BATCH file?

by

for this purpose I use the following:

set LogFile=somepath\logfile.txt
set logg=^> _^&type _^&type _^>^>%LogFile%
echo this goes to screen AND file! %logg%

This is a bit tricky.
So let’s disassemble that line to four parts:

set logg=      ^> _          ^&type _           ^&type _^>^>%LogFile%

The Idea is to print the line to a temporary file (named _) (second part)
then type the contents of that file to screen (third part)
then type it to the logfile (fourth part).

Put that all to a variable (first part), so you don’t have to type that monsterstring to every line. (this is the reason why the > and & are escaped with ^)

So every time you use 

echo whatever %logg%

it will appear on the screen AND write to %logfile%

Note that this will also work:

 %logg% echo whatever

Edit djangofan:
Also, you can do it with functions:

@ECHO off
:: do not enable delayed expansion since it will break this method
SETLOCAL ENABLEEXTENSIONS
SET LogFile=logfile.out
SET Logg=^> tmp.out^&^& type tmp.out^&^&type tmp.out^>^>%LogFile%

CALL :logit "This is my message!"
CALL :logit "Hear my thunder?"

GOTO :end
:logit
ECHO %~1 %Logg%
DEL /Q tmp.out
EXIT /B 0
:end
pause

Edit Stephan:
If you use CALL, the %logg% would be overkill. In that case I would just use:

:logit
echo %~1
echo %date%,%time% - %~1 >>logfile
exit /b 0

This might be the best solution to the original question, because the Date/Time will be written into logfile, but not on the screen.
Btw: you don’t have to delete the tempfile every time you use it, just delete it one time, just before the batch ends.

More Related Contents:

  1. Batch file to split .csv file
  2. How do I minimize the command prompt from my bat file
  3. batch file Copy files with certain extensions from multiple directories into one directory
  4. How can you find and replace text in a file using the Windows command-line environment?
  5. How do I run two commands in one line in Windows CMD?
  6. How to check if a process is running via a batch script
  7. How to echo with different colors in the Windows command line [closed]
  8. Parallel execution of shell processes
  9. How to run a PowerShell script without displaying a window?
  10. Escape percent in bat file
  11. Windows Batch File Looping Through Directories to Process Files?
  12. Secure FTP using Windows batch script
  13. How to use passive FTP mode in Windows command prompt?
  14. Capture output command CMD
  15. Why does ECHO command print some extra trailing space into the file?
  16. How to create batch file in Windows using “start” with a path and command with spaces
  17. Is there a way to redirect ONLY stderr to stdout (not combine the two) so it can be piped to other programs?
  18. Why does only the first line of this Windows batch file execute but all three lines execute in a command shell?
  19. Running another program in Windows bat file and not create child process
  20. How to echo “2” (no quotes) to a file, from a batch script?
  21. Why does this batch variable never change even when set?
  22. Error “‘git’ is not recognized as an internal or external command”
  23. File is older than 4 minutes in Batch file
  24. Command line for looking at specific port
  25. Path prefixes \??\ and \\?\
  26. Windows console %DATE% Math
  27. Batch goto loses errorlevel
  28. Escape percent signs in given variables
  29. Out of a git console: how do I execute a batch file and then return to git console?
  30. UTF-16 to UTF-8 conversion (for scripting in Windows)

Leave a Comment