How to make DateTime::Duration output only in days?

by

At first you need to do the correct subtraction. There exists delta_md, delta_days, delta_ms and subtract_datetime_absolute. Depending on which unit you later want, you need to pick the right subtraction. The problem is that not every unit is convertible later without time_zone information. Thats the reason why you need to pick the correct delta method.

For example a day can have 23 Hours or 24 or 25 Hours, depending on the time zone. Because of that, you need to specify how the subtraction should work. Because you want the days later, the subtraction need to focus on days, rather focus on hours. Don’t use the overload feature, because it only does a best fit.

That means you need to do a delta_days subtraction.

my $dur = $date->delta_days($today);

Now $dur is a DateTime::Duration object. You need to knew that it always tries to best fit the days, weeks, years, months if possible. That means your days will split in weeks and days. Because this conversion is always a constant.

If you don’t want this “best fit” you need to call the in_units method and convert it only to days.

my $days = $dur->in_units('days');

But like i said before in_units only can do a conversion where it is possible. A call with in_units('hours') will not work on this object and just return a zero because you cant convert days to hours. If you want hours for example, you need to do a delta_ms, and on this object you can call in_units('hours')

The complete example:

#!/usr/bin/env perl
use 5.010;
use strict;
use warnings;

use DateTime;
use DateTime::Format::Strptime;

my $date = "23/05-2022";
my $parser = DateTime::Format::Strptime->new(
    pattern     => '%d/%m-%Y',
    time_zone   => 'local',
);
$date = $parser->parse_datetime($date);

my $today = DateTime->new(
    day   => 1,
    month => 7,
    year  => 2011,
    time_zone => 'local'
);  

my $dur = $date->delta_days($today);
say "Weeks:          ", $dur->weeks;
say "Days:           ", $dur->days;
say "Absolute Days:  ", $dur->in_units('days');
say "Absolute Hours: ", $date->delta_ms($today)->in_units('hours');

The output of this program is:

Weeks:          568
Days:           3
Absolute Days:  3979
Absolute Hours: 95496

And just for info:
1) You don’t need to load DateTime::Duration its get loaded with DateTime.
2) You dont need (). These modules are OOP and don’t export/import anything.

More Related Contents:

  1. Failing to install MIME::Base64 using cpan [closed]
  2. Declaring a 2D coordinate in Perl / C / C++ [closed]
  3. how to use multiple IP’s in perl script
  4. Why can’t Perl find my file that is in ClearCase?
  5. How can I use a variable as a variable name in Perl?
  6. How can I use a new Perl module without install permissions?
  7. Difference of Two Arrays Using Perl
  8. How can I output UTF-8 from Perl?
  9. What’s the difference between a hash and hash reference in Perl?
  10. Multiline search replace with Perl
  11. How do I “use” a Perl module in a directory not in @INC?
  12. How can I process options using Perl in -n or -p mode?
  13. How can I hook into Perl’s print?
  14. How can I dynamically include Perl modules without using eval?
  15. Why do my Perl tests fail with use encoding ‘utf8’?
  16. How can I compile my Perl script so it can be executed on systems without ‘perl’ installed?
  17. How can I guess the encoding of a string in Perl?
  18. What is the difference between Perl’s ( or, and ) and ( ||, && ) short-circuit operators?
  19. Using output from a previous job in a new one in a GitHub Action
  20. What does !! (double exclamation point) mean?
  21. Using my with parentheses and only one variable
  22. Obtain a switch/case behaviour in Perl 5
  23. Do you use an exception class in your Perl programs? Why or why not?
  24. How do I extract the domain out of an URL?
  25. Why does $foo->{bar} autovivify but %$foo doesn’t?
  26. In Perl, is it better to use a module than to require a file?
  27. Demystifying the Perl glob (*)
  28. Why does !1 give me nothing in Perl?
  29. How do I retrieve the terminal width in Perl?
  30. How do I tell CPAN to install all dependencies?

Leave a Comment