How to print lines between two patterns, inclusive or exclusive (in sed, AWK or Perl)?

by

Print lines between PAT1 and PAT2

$ awk '/PAT1/,/PAT2/' file
PAT1
3    - first block
4
PAT2
PAT1
7    - second block
PAT2
PAT1
10    - third block

Or, using variables:

awk '/PAT1/{flag=1} flag; /PAT2/{flag=0}' file

How does this work?

  • /PAT1/ matches lines having this text, as well as /PAT2/ does.
  • /PAT1/{flag=1} sets the flag when the text PAT1 is found in a line.
  • /PAT2/{flag=0} unsets the flag when the text PAT2 is found in a line.
  • flag is a pattern with the default action, which is to print $0: if flag is equal 1 the line is printed. This way, it will print all those lines occurring from the time PAT1 occurs and up to the next PAT2 is seen. This will also print the lines from the last match of PAT1 up to the end of the file.

Print lines between PAT1 and PAT2 – not including PAT1 and PAT2

$ awk '/PAT1/{flag=1; next} /PAT2/{flag=0} flag' file
3    - first block
4
7    - second block
10    - third block

This uses next to skip the line that contains PAT1 in order to avoid this being printed.

This call to next can be dropped by reshuffling the blocks: awk '/PAT2/{flag=0} flag; /PAT1/{flag=1}' file.

Print lines between PAT1 and PAT2 – including PAT1

$ awk '/PAT1/{flag=1} /PAT2/{flag=0} flag' file
PAT1
3    - first block
4
PAT1
7    - second block
PAT1
10    - third block

By placing flag at the very end, it triggers the action that was set on either PAT1 or PAT2: to print on PAT1, not to print on PAT2.

Print lines between PAT1 and PAT2 – including PAT2

$ awk 'flag; /PAT1/{flag=1} /PAT2/{flag=0}' file
3    - first block
4
PAT2
7    - second block
PAT2
10    - third block

By placing flag at the very beginning, it triggers the action that was set previously and hence print the closing pattern but not the starting one.

Print lines between PAT1 and PAT2 – excluding lines from the last PAT1 to the end of file if no other PAT2 occurs

This is based on a solution by Ed Morton.

awk 'flag{
        if (/PAT2/)
           {printf "%s", buf; flag=0; buf=""}
        else
            buf = buf $0 ORS
     }
     /PAT1/ {flag=1}' file

As a one-liner:

$ awk 'flag{ if (/PAT2/){printf "%s", buf; flag=0; buf=""} else buf = buf $0 ORS}; /PAT1/{flag=1}' file
3    - first block
4
7    - second block

# note the lack of third block, since no other PAT2 happens after it

This keeps all the selected lines in a buffer that gets populated from the moment PAT1 is found. Then, it keeps being filled with the following lines until PAT2 is found. In that point, it prints the stored content and empties the buffer.

More Related Contents:

  1. How to select lines between two marker patterns which may occur multiple times with awk/sed
  2. shell – remove numbers from a string column [closed]
  3. How can I delete a newline if it is the last character in a file?
  4. Do a tail -F until matching a pattern
  5. Awk replace a column with its hash value
  6. Enhancement of unix script [closed]
  7. Get lines between two patterns
  8. How can I manipulate text in bash? [closed]
  9. Bash tool to get nth line from a file
  10. Find and replace in file and overwrite file doesn’t work, it empties the file
  11. How to delete duplicate lines in a file without sorting it in Unix
  12. How to use multiple arguments for awk with a shebang (i.e. #!)?
  13. Insert line after match using sed
  14. sed whole word search and replace
  15. How can I quickly sum all numbers in a file?
  16. How to insert a newline in front of a pattern?
  17. Alternative to `sed -i` on Solaris
  18. How to get the second column from command output?
  19. How can I check the version of sed in OS X?
  20. What are the differences between Perl, Python, AWK and sed? [closed]
  21. Sed to extract text between two strings
  22. Insert multiple lines into a file after specified pattern using shell script
  23. Trim leading and trailing spaces from a string in awk
  24. How can I pass variables from awk to a shell command?
  25. How to use shell variables in perl command call in a bash shell script?
  26. how to delete the duplicate lines in file except the first matched line
  27. Replace whitespace with a comma in a text file in Linux
  28. How to add text at the end of each line in unix
  29. How to print 5 consecutive lines after a pattern in file using awk [duplicate]
  30. How to grep for case insensitive string in a file?

Leave a Comment