multiplot – stacking 3 graphs on a larger canvas

by

In order to use a bigger canvas, you must use the size option when setting the terminal, e.g.:

set terminal postscript eps enhanced size 10cm,15cm

set size just changes the plot size relative to your canvas. To see this, consider

set terminal wxt
set size 1.0,1.5
plot sin(x)

Parts of the plot disappear, because it is much too high with respect to the canvas.

To stack three plots with same heights, in my opinion its best to use fixed margins:

set terminal pngcairo size 600, 900
set output 'stacking.png'

set lmargin at screen 0.15
set rmargin at screen 0.95

TOP=0.98
DY = 0.29

set multiplot
set offset 0,0,graph 0.05, graph 0.05

set xlabel 'time'
set ylabel 'ylabel 1' offset 1
set tmargin at screen TOP-2*DY
set bmargin at screen TOP-3*DY
set ytics -1000,500,1000
plot 1150*cos(x) title 'First'

set xtics format ''
unset xlabel
set ylabel 'ylabel 2' offset 0
set tmargin at screen TOP-DY
set bmargin at screen TOP-2*DY
set ytics -100,50,100
plot 101*sin(x) title 'Second'

set ylabel 'ylabel 3' offset -1
set tmargin at screen TOP
set bmargin at screen TOP-DY
set ytics -8,4,8
plot 10*sin(2*x) title 'Third'

unset multiplot; set output

The result is (with 4.6.3):

enter image description here

In order to avoid overlapping labels of the ytics, you must change the range where the tics are drawn, e.g. with set ytics -100,50,100, which puts ytics between -100 and 100 in steps of 50. Using set ytics rangelimited doesn’t work

To increase the distance between the plot curve and the border, use set offset with graph coordinates, like done in the above script.

I started with the lowest plot, because only that has x labels and an xlabel.

More Related Contents:

  1. Gnuplot line types
  2. Histogram using gnuplot?
  3. gnuplot: load datafile 1:1 into datablock
  4. Get ratio from 2 files in gnuplot
  5. Loop structure inside gnuplot?
  6. Removing blank gap in gnuplot multiplot
  7. Hatch patterns in gnuplot
  8. Add a single point at an existing plot
  9. How to get the distance between automatic generated gnuplot tics?
  10. pipe plot data to gnuplot script
  11. How to plot data without a separate file by specifying all points inside the Gnuplot script?
  12. gnuplot 2D polar plot with heatmap from 3D dataset – possible?
  13. How to pass command line argument to gnuplot?
  14. gnuplot: apply colornames from datafile
  15. Making C code plot a graph automatically
  16. How do you plot bar charts in gnuplot?
  17. How to make points one color when a third column equals zero, and another color otherwise, in Gnuplot?
  18. Gnuplot plotting data from a file up to some row
  19. gnuplot linecolor variable in matplotlib?
  20. Line plot in GnuPlot where line color is a third column in my data file?
  21. Gnuplot: conditional plotting ($2 == 15 ? $2 : ‘1/0’) with lines
  22. How do I plot list of tuples in Python?
  23. How to define and access array in GNUplot?
  24. problematic Moire pattern in image produced with gnuplot pm3d and pdf output
  25. Octave-Gnuplot-AquaTerm error: set terminal aqua enhanced title “Figure 1″…unknown terminal type”
  26. Plotting labeled intervals in matplotlib/gnuplot
  27. gnuplot store one number from data file into variable
  28. Gnuplot: How to load and display single numeric value from data file
  29. create heatmap2d from txt file
  30. Fitting a curve to specific data

Leave a Comment