What use is find_package() when you need to specify CMAKE_MODULE_PATH?

by

Command find_package has two modes: Module mode and Config mode. You are trying to
use Module mode when you actually need Config mode.

Module mode

Find<package>.cmake file located within your project. Something like this:

CMakeLists.txt
cmake/FindFoo.cmake
cmake/FindBoo.cmake

CMakeLists.txt content:

list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
find_package(Foo REQUIRED) # FOO_INCLUDE_DIR, FOO_LIBRARIES
find_package(Boo REQUIRED) # BOO_INCLUDE_DIR, BOO_LIBRARIES

include_directories("${FOO_INCLUDE_DIR}")
include_directories("${BOO_INCLUDE_DIR}")
add_executable(Bar Bar.hpp Bar.cpp)
target_link_libraries(Bar ${FOO_LIBRARIES} ${BOO_LIBRARIES})

Note that CMAKE_MODULE_PATH has high priority and may be usefull when you need to rewrite standard Find<package>.cmake file.

Config mode (install)

<package>Config.cmake file located outside and produced by install
command of other project (Foo for example).

foo library:

> cat CMakeLists.txt 
cmake_minimum_required(VERSION 2.8)
project(Foo)

add_library(foo Foo.hpp Foo.cpp)
install(FILES Foo.hpp DESTINATION include)
install(TARGETS foo DESTINATION lib)
install(FILES FooConfig.cmake DESTINATION lib/cmake/Foo)

Simplified version of config file:

> cat FooConfig.cmake 
add_library(foo STATIC IMPORTED)
find_library(FOO_LIBRARY_PATH foo HINTS "${CMAKE_CURRENT_LIST_DIR}/../../")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION "${FOO_LIBRARY_PATH}")

By default project installed in CMAKE_INSTALL_PREFIX directory:

> cmake -H. -B_builds
> cmake --build _builds --target install
-- Install configuration: ""
-- Installing: /usr/local/include/Foo.hpp
-- Installing: /usr/local/lib/libfoo.a
-- Installing: /usr/local/lib/cmake/Foo/FooConfig.cmake

Config mode (use)

Use find_package(... CONFIG) to include FooConfig.cmake with imported target foo:

> cat CMakeLists.txt 
cmake_minimum_required(VERSION 2.8)
project(Boo)

# import library target `foo`
find_package(Foo CONFIG REQUIRED)

add_executable(boo Boo.cpp Boo.hpp)
target_link_libraries(boo foo)
> cmake -H. -B_builds -DCMAKE_VERBOSE_MAKEFILE=ON
> cmake --build _builds
Linking CXX executable Boo
/usr/bin/c++ ... -o Boo /usr/local/lib/libfoo.a

Note that imported target is highly configurable. See my answer.

Update

More Related Contents:

  1. Using CMake with GNU Make: How can I see the exact commands?
  2. CMake: use a custom linker
  3. CMake add_custom_command not being run
  4. Looking for a ‘cmake clean’ command to clear up CMake output
  5. How to set warning level in CMake?
  6. How to set linker flags for OpenMP in CMake’s try_compile function
  7. Compile with /MT instead of /MD using CMake
  8. Copy file from source directory to binary directory using CMake
  9. How to make CMake reconfiguration depend on custom file?
  10. Listing include_directories in CMake
  11. Recursive list of LINK_LIBRARIES in CMake
  12. CMake – linking to library downloaded from ExternalProject_add()
  13. Building a tool immediately so it can be used later in same CMake run
  14. How to instruct CMake to use the build architecture compiler
  15. What is a CMake generator?
  16. Add Source in a subdirectory to a cmake project
  17. Correct way to use third-party libraries in cmake project
  18. CMake compare to empty string with STREQUAL failed
  19. CMake how to set the build directory to be different than source directory
  20. How to always run command when building regardless of any dependency?
  21. How to Trace CMakeLists.txt [duplicate]
  22. How to run ctest after building my project with cmake
  23. Add all files under a folder to a CMake glob?
  24. How to use CMake to find and link to a library using install-export and find_package?
  25. How do I include a literal double quote in a custom CMake command?
  26. Postpone making custom target until install
  27. CMake : Changing name of Visual Studio and Xcode exectuables depending on configuration in a project generated by CMake
  28. Why add header files into the add_library/add_executable commands in CMake?
  29. CMake and finding other projects and their dependencies
  30. How to add a custom build type to CMake? (targeting make)

Leave a Comment