XSLT – How to keep only wanted elements from XML

by

This general transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ns="some:ns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <ns:WhiteList>
  <name>ns:currency</name>
  <name>ns:currency_code3</name>
 </ns:WhiteList>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "*[not(descendant-or-self::*[name()=document('')/*/ns:WhiteList/*])]"/>
</xsl:stylesheet>

when applied on the provided XML document (with namespace definition added to make it well-formed):

<ns:stuff xmlns:ns="some:ns">
    <ns:things>
        <ns:currency>somecurrency</ns:currency>
        <ns:currency_code/>
        <ns:currency_code2/>
        <ns:currency_code3/>
        <ns:currency_code4/>
    </ns:things>
</ns:stuff>

produces the wanted result (white-listed elements and their structural relations are preserved):

<ns:stuff xmlns:ns="some:ns">
   <ns:things>
      <ns:currency>somecurrency</ns:currency>
      <ns:currency_code3/>
   </ns:things>
</ns:stuff>

Explanation:

  1. The identity rule/template copies all nodes “as-is”.

  2. The stylesheet contains a top-level <ns:WhiteList> element whose <name> children specify all white-listed element’s names — the elements that are to be preserved with their structural relationships in the document.

  3. The <ns:WhiteList> element is best kept in a separate document so that the current stylesheet will not need to be edited with new names. Here the whitelist is in the same stylesheet just for convenience.

  4. One single template is overriding the identity template. It doesn’t process (deletes) any element that is not white-listed and has no descendent that is white-listed.

More Related Contents:

  1. Current node vs. Context node in XSLT/XPath?
  2. XPath select all elements between two specific elements
  3. XSLT: How to convert XML Node to String
  4. XPath with multiple conditions
  5. Is there an XSLT name-of element?
  6. How do you output the current element path in XSLT?
  7. Finding the difference between two dateTimes in XSLT
  8. XSLT Replace function not found
  9. What is the difference between ‘or’ and ‘|’ when programming in xslt?
  10. Concatenate multiple node values in xpath
  11. WiX Installer: using xslt with heat.exe to update attributes
  12. How do I generate a comma-separated list with XSLT/XPath?
  13. XSLT – Comparing preceding-sibling’s elements with current’s node element
  14. XML to CSV Using XSLT
  15. How to fix error: The markup in the document following the root element must be well-formed
  16. How to use XPath contains() here?
  17. How to read large xml file without loading it in memory and using XElement
  18. How to declare XPath namespaces in xmlstarlet?
  19. What is the XPath to select a range of nodes?
  20. Navigating XML nodes in VBScript, for a Dummy
  21. Incrementing and checking the counter variable in XSLT
  22. How to select a node using XPath if sibling node has a specific value?
  23. For loops vs. apply-templates
  24. What is the difference between root node, root element and document element in XML?
  25. How to remove namespaces from XML using XSLT
  26. How to link up XML file with XSLT file?
  27. XSLT to order attributes
  28. Converting XML to escaped text in XSLT
  29. XSLT Transformation – dynamic element names
  30. Converting XML elements to XML attributes using XSLT

Leave a Comment