How to list all folder with size via batch file

by

For each folder in the list, use dir command to retrieve the size of the files under the folder

@echo off
    setlocal disabledelayedexpansion

    set "folder=%~1"
    if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        echo(%%~nxa # !size!
        endlocal
    )

    endlocal

It iterates over the indicated folder (passed as parameter to the batch file, or current directory if there is no paramter).

For each folder inside it (for /d) a recursive dir command is executed inside the inner for command, and from its output, the summary line at the end (extracted by findstr) is parsed (the tokens in for command) and the total size of all the files under this subfolder is retrieved. Then the name (and extension if it has) of the folder and the size of the elements under it is echoed to console.

If a file needs to be created, redirect the output of the batch to a file

getSizes.cmd "c:\temp" > C:\folderList.txt

More Related Contents:

  1. How to delete files/subfolders in a specific directory at the command prompt in Windows
  2. How to get windows batch’s parent folder
  3. Batch create folders based on part of file name and move files into that folder
  4. Variables are not behaving as expected
  5. Single line with multiple commands using Windows batch file
  6. Where is “START” searching for executables?
  7. What does %~d0 mean in a Windows batch file?
  8. How to run a PowerShell script from a batch file
  9. How can you zip or unzip from the script using ONLY Windows’ built-in capabilities?
  10. Run batch file as a Windows service
  11. windows batch SET inside IF not working
  12. How can I run a program from a batch file without leaving the console open after the program starts?
  13. How to check if a file exists from inside a batch file [duplicate]
  14. Batch files: List all files in a directory with relative paths
  15. Windows batch script to parse CSV file and output a text file
  16. Using parameters in batch files at Windows command line
  17. How to create an infinite loop in Windows batch file?
  18. Convert a small PS script into a long line in a .BATch file
  19. Kill a Process by Looking up the Port being used by it from a .BAT
  20. What is the easiest way to reset ERRORLEVEL to zero?
  21. Remove unwanted path name from %path% variable via batch
  22. How to count no of lines in text file and store the value into a variable using batch script?
  23. How to test if a path is a file or directory in Windows batch file?
  24. Split string with string as delimiter
  25. How to change Screen buffer size in Windows Command Prompt from batch script
  26. Delete all files and folders in a directory
  27. Foolproof way to check for nonzero (error) return code in windows batch file
  28. Windows batch script to delete everything in a folder except one
  29. ERRORLEVEL vs %ERRORLEVEL% vs exclamation mark ERRORLEVEL exclamation mark
  30. Create a list or an array and print each item in Windows Batch

Leave a Comment