Single line with multiple commands using Windows batch file

by

& between two commands simply results in executing both commands independent on result of first command. The command right of & is executed after command left of & finished independent on success or error of the previous command, i.e. independent on exit / return value of previous command.

&& results in a conditional execution of second command. The second command is executed only if first command was successful which means exited with return code 0.

For an alternate explanation see Conditional Execution.

dir & md folder1 & rename folder1 mainfolder

is therefore equal

dir
md folder1
rename folder1 mainfolder

A multiline replacement for

dir && md folder1 && rename folder1 mainfolder

would be

dir
if not errorlevel 1 (
   md folder1
   if not errorlevel 1 (
      rename folder1 mainfolder
   )
)

if not errorlevel 1 means the command before did not terminate with an exit code greater 0. As the commands dir and md never exit with a negative value, just with 0 or greater (as nearly all commands and console applications) and value 0 is the exit code for success, this is a correct method to test on successful execution of dir and md.

Other helpful Stack Overflow topics about errorlevel:

Care must be taken on mixing unconditional operator & with conditional operators like && and || because of the execution order is not necessarily the order of the commands on command line.

Example:

dir "C:\Users\%UserName%" /AD 2>nul || dir "%UserProfile%" /AD & echo User profile path: "%UserProfile%"

This command line is executed as:

dir "C:\Users\%UserName%" /AD 2>nul
if errorlevel 1 dir "%UserProfile%" /AD
echo User profile path: "%UserProfile%"

The ECHO command is always executed independent on result of execution of first DIR whereas second DIR is executed only if first DIR fails like on Windows XP or the user’s profile folder is not on drive C: or not in a folder Users at all.

It is necessary to use ( and ) on executing ECHO only if first DIR fails after second DIR independent on result of second DIR.

dir "C:\Users\%UserName%" /AD 2>nul || ( dir "%UserProfile%" /AD & echo User profile path: "%UserProfile%" )

This command line is executed as:

dir "C:\Users\%UserName%" /AD 2>nul
if errorlevel 1 (
    dir "%UserProfile%" /AD
    echo User profile path: "%UserProfile%"
)

For the answer on third question see my answer on How to call a batch file in the parent folder of current batch file? where I have explained the differences on running a batch file with command call or with command start or with none of those two commands from within a batch file.

More Related Contents:

  1. How do I run two commands in one line in Windows CMD?
  2. Batch command date and time in file name
  3. Stop and Start a service via batch or cmd file?
  4. Create an empty file on the commandline in windows (like the linux touch command)
  5. Windows shell command to get the full path to the current directory?
  6. How do I minimize the command prompt from my bat file
  7. Why doesn’t my stderr redirection end after command finishes? And how do I fix it?
  8. Variables are not behaving as expected
  9. Batch file to delete files older than N days
  10. How to have multiple colors in a Windows batch file?
  11. How do I measure execution time of a command on the Windows command line?
  12. Iterate all files in a directory using a ‘for’ loop
  13. How to wait all batch files to finish before exiting?
  14. Windows Batch Variables Won’t Set
  15. ‘Pretty print’ windows %PATH% variable – how to split on ‘;’ in CMD shell
  16. How to verify if a file exists in a batch file?
  17. Windows command to convert Unix line endings?
  18. Set a persistent environment variable from cmd.exe
  19. IF… OR IF… in a windows batch file
  20. How to run a PowerShell script within a Windows batch file
  21. Counting in a FOR loop using Windows Batch script
  22. How to count no of lines in text file and store the value into a variable using batch script?
  23. How to test if a path is a file or directory in Windows batch file?
  24. Split string with string as delimiter
  25. How to change Screen buffer size in Windows Command Prompt from batch script
  26. Delete all files and folders in a directory
  27. Remove trailing spaces from a file using Windows batch?
  28. How can I source variables from a .bat file into a PowerShell script?
  29. How to expand a CMD shell variable twice (recursively)
  30. Split %date% in a batch file regardless of Regional Settings

Leave a Comment