Text garble in batch script for wmic command

by

Your problem is SYSTEMINFO produces ANSII output (as do most commands), but WMIC produces Unicode output. The two do not mix well.

Below are three solutions that all produce ANSII output.

1) Pipe the WMIC output to MORE

MORE converts Unicode to ANSII. I also pipe that result to FINDSTR to eliminate blank lines. The only problem with this solution is that a quirk with the conversions causes the WMIC output to have an extra carriage return at the end of each line (<CR><CR><LF> instead of <CR><LF>)

@echo OFF
>test1.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  wmic cpu get Name /Format:list | more | findstr .
  wmic computersystem get NumberofProcessors /Format:list | more | findstr .

  echo(
  echo NIC Information:
  wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list | more | findstr .
)

——————————

The remaining solutions are all properly formatted, without any extra <CR>

2) Write WMIC output to a temp file, followed by TYPE

The temp file is in Unicode format, and TYPE properly converts the Unicode to ANSII. I still pipe the result to FINDSTR to eliminate blank lines.

@echo OFF
>test2.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
wmic %* >test.tmp
type test.tmp | findstr .
del test.tmp
exit /b

3) Run WMIC through two FOR /F loops.

The first FOR /F converts the WMIC output to ANSII, but it has the extra <CR> at the end of each line. The second FOR /F strips off the unwanted trailing <CR>. FOR /F automatically strips blank lines.

@echo OFF
>test3.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
for /f "delims=" %%A in ('"wmic %*"') do for /f "delims=" %%B in ("%%A") do echo %%B
exit /b

More Related Contents:

  1. How to correct variable overwriting misbehavior when parsing output?
  2. Why is the FOR /f loop in this batch script evaluating a blank line?
  3. How can you find and replace text in a file using the Windows command-line environment?
  4. How do I run two commands in one line in Windows CMD?
  5. How to check if a process is running via a batch script
  6. How to echo with different colors in the Windows command line [closed]
  7. Parallel execution of shell processes
  8. How to run a PowerShell script without displaying a window?
  9. Escape percent in bat file
  10. Windows Batch File Looping Through Directories to Process Files?
  11. Secure FTP using Windows batch script
  12. Capture output command CMD
  13. Why does ECHO command print some extra trailing space into the file?
  14. How to create batch file in Windows using “start” with a path and command with spaces
  15. Is there a way to redirect ONLY stderr to stdout (not combine the two) so it can be piped to other programs?
  16. Why does only the first line of this Windows batch file execute but all three lines execute in a command shell?
  17. Batch file to split .csv file
  18. Running another program in Windows bat file and not create child process
  19. How to echo “2” (no quotes) to a file, from a batch script?
  20. Why does this batch variable never change even when set?
  21. echo -e equivalent in Windows?
  22. How do I make a log of all ECHO commands in a BATCH file?
  23. How do I minimize the command prompt from my bat file
  24. batch file Copy files with certain extensions from multiple directories into one directory
  25. Path prefixes \??\ and \\?\
  26. Windows console %DATE% Math
  27. Foolproof way to check for nonzero (error) return code in windows batch file
  28. Windows batch script to delete everything in a folder except one
  29. ERRORLEVEL vs %ERRORLEVEL% vs exclamation mark ERRORLEVEL exclamation mark
  30. Create a list or an array and print each item in Windows Batch

Leave a Comment