Calculate time difference in Windows batch file

by 
@echo off

rem Get start time:
for /F "tokens=1-4 delims=:.," %%a in ("%time%") do (
   set /A "start=(((%%a*60)+1%%b %% 100)*60+1%%c %% 100)*100+1%%d %% 100"
)

rem Any process here...

rem Get end time:
for /F "tokens=1-4 delims=:.," %%a in ("%time%") do (
   set /A "end=(((%%a*60)+1%%b %% 100)*60+1%%c %% 100)*100+1%%d %% 100"
)

rem Get elapsed time:
set /A elapsed=end-start

rem Show elapsed time:
set /A hh=elapsed/(60*60*100), rest=elapsed%%(60*60*100), mm=rest/(60*100), rest%%=60*100, ss=rest/100, cc=rest%%100
if %mm% lss 10 set mm=0%mm%
if %ss% lss 10 set ss=0%ss%
if %cc% lss 10 set cc=0%cc%
echo %hh%:%mm%:%ss%,%cc%

EDIT 2017-05-09: Shorter method added

I developed a shorter method to get the same result, so I couldn’t resist to post it here. The two for commands used to separate time parts and the three if commands used to insert leading zeros in the result are replaced by two long arithmetic expressions, that could even be combined into a single longer line.

The method consists in directly convert a variable with a time in “HH:MM:SS.CC” format into the formula needed to convert the time to centiseconds, accordingly to the mapping scheme given below:

       HH        :      MM        :      SS        .       CC

(((10  HH  %%100)*60+1  MM  %%100)*60+1  SS  %%100)*100+1  CC  %%100

That is, insert (((10 at beginning, replace the colons by %%100)*60+1, replace the point by %%100)*100+1 and insert %%100 at end; finally, evaluate the resulting string as an arithmetic expression. In the time variable there are two different substrings that needs to be replaced, so the conversion must be completed in two lines. To get an elapsed time, use (endTime)-(startTime) expression and replace both time strings in the same line.

EDIT 2017/06/14: Locale independent adjustment added

EDIT 2020/06/05: Pass-over-midnight adjustment added

@echo off
setlocal EnableDelayedExpansion

set "startTime=%time: =0%"

set /P "=Any process here..."

set "endTime=%time: =0%"



rem Get elapsed time:
set "end=!endTime:%time:~8,1%=%%100)*100+1!"  &  set "start=!startTime:%time:~8,1%=%%100)*100+1!"
set /A "elap=((((10!end:%time:~2,1%=%%100)*60+1!%%100)-((((10!start:%time:~2,1%=%%100)*60+1!%%100), elap-=(elap>>31)*24*60*60*100"

rem Convert elapsed time to HH:MM:SS:CC format:
set /A "cc=elap%%100+100,elap/=100,ss=elap%%60+100,elap/=60,mm=elap%%60+100,hh=elap/60+100"

echo Start:    %startTime%
echo End:      %endTime%
echo Elapsed:  %hh:~1%%time:~2,1%%mm:~1%%time:~2,1%%ss:~1%%time:~8,1%%cc:~1%

You may review a detailed explanation of this method at this answer.

More Related Contents:

  1. How do I measure execution time of a command on the Windows command line?
  2. Variables are not behaving as expected
  3. Single line with multiple commands using Windows batch file
  4. Where is “START” searching for executables?
  5. What does %~d0 mean in a Windows batch file?
  6. How to run a PowerShell script from a batch file
  7. How to code a BAT file to always run as admin mode?
  8. How can you zip or unzip from the script using ONLY Windows’ built-in capabilities?
  9. Run batch file as a Windows service
  10. windows batch SET inside IF not working
  11. How can I run a program from a batch file without leaving the console open after the program starts?
  12. Copy text from a Windows CMD window to clipboard
  13. What does symbol ^ mean in Batch script?
  14. How to run a PowerShell script within a Windows batch file
  15. Resolve absolute path from relative path and/or file name
  16. cmd is somehow writing Chinese text as output
  17. How to count no of lines in text file and store the value into a variable using batch script?
  18. How to test if a path is a file or directory in Windows batch file?
  19. Rename multiple files in cmd
  20. Split string with string as delimiter
  21. How to change Screen buffer size in Windows Command Prompt from batch script
  22. Delete all files and folders in a directory
  23. How to append a date in batch files
  24. How can I source variables from a .bat file into a PowerShell script?
  25. Windows Batch file to echo a specific line number
  26. Batch create folders based on part of file name and move files into that folder
  27. How to expand a CMD shell variable twice (recursively)
  28. Split %date% in a batch file regardless of Regional Settings
  29. Windows Batch: Set Variables from Text File
  30. Global NPM package installed but command not found

Leave a Comment