Does xslt have split() function?

by

In XSLT 1.0 you have to built a recursive template. This stylesheet:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text/text()" name="tokenize">
        <xsl:param name="text" select="."/>
        <xsl:param name="separator" select="','"/>
        <xsl:choose>
            <xsl:when test="not(contains($text, $separator))">
                <item>
                    <xsl:value-of select="normalize-space($text)"/>
                </item>
            </xsl:when>
            <xsl:otherwise>
                <item>
                    <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
                </item>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Input:

<root>
<text>Item1, Item2, Item3</text>
</root>

Output:

<root>
    <text>
        <item>Item1</item>
        <item>Item2</item>
        <item>Item3</item>
    </text>
</root>

In XSLT 2.0 you have the tokenize() core function. So, this stylesheet:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text/text()" name="tokenize">
        <xsl:param name="separator" select="','"/>
        <xsl:for-each select="tokenize(.,$separator)">
                <item>
                    <xsl:value-of select="normalize-space(.)"/>
                </item>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Result:

<root>
    <text>
        <item>Item1</item>
        <item>Item2</item>
        <item>Item3</item>
    </text>
</root>

More Related Contents:

  1. Is there a function to split a string in PL/SQL?
  2. How can I convert a string to upper- or lower-case with XSLT?
  3. How to split a string into substrings of a given length? [duplicate]
  4. T-SQL Split Word into characters
  5. Is there a function to split a string in Oracle PL/SQL?
  6. scala string.split does not work
  7. How to parse string to date in xslt 2.0
  8. How to split a string by a string in Scala
  9. How to compare strings in Bash
  10. Splitting a string at every n-th character
  11. Convert Int to String in Swift
  12. How to split a string in Java
  13. What are the differences between Rust’s `String` and `str`?
  14. How can I convert a comma-separated string to an array?
  15. How do I remove the file suffix and path portion from a path string in Bash?
  16. How to split strings into text and number?
  17. In Perl, how can I read an entire file into a string?
  18. Split a string with delimiters but keep the delimiters in the result in C#
  19. Replace whole line containing a string using Sed
  20. Python: most idiomatic way to convert None to empty string?
  21. Is there a way to split a string by every nth separator in Python?
  22. Integer PadLeft function in T-SQL
  23. Convert specified column in a multi-line string into single comma-separated line
  24. Java split String performances
  25. Get values between curly braces c#
  26. Swift – Split string over multiple lines
  27. Groovy String to Date
  28. What is the difference between VBScript’s + and & operator?
  29. Splitting a math expression string into tokens in Python
  30. Split a string column into several dummy variables

Leave a Comment