How do you get the string length in a batch file?

by

As there is no built in function for string length, you can write your own function like this one: 

@echo off
setlocal
REM *** Some tests, to check the functionality ***
REM *** An emptyStr has the length 0
set "emptyString="
call :strlen result emptyString
echo %result%

REM *** This string has the length 14
set "myString=abcdef!%%^^()^!"
call :strlen result myString
echo %result%

REM *** This string has the maximum length of 8191
setlocal EnableDelayedExpansion
set "long=."
FOR /L %%n in (1 1 13) DO set "long=!long:~-4000!!long:~-4000!"
(set^ longString=!long!!long:~-191!)

call :strlen result longString
echo %result%

goto :eof

REM ********* function *****************************
:strlen <resultVar> <stringVar>
(   
    setlocal EnableDelayedExpansion
    (set^ tmp=!%~2!)
    if defined tmp (
        set "len=1"
        for %%P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
            if "!tmp:~%%P,1!" NEQ "" ( 
                set /a "len+=%%P"
                set "tmp=!tmp:~%%P!"
            )
        )
    ) ELSE (
        set len=0
    )
)
( 
    endlocal
    set "%~1=%len%"
    exit /b
)

This function needs always 13 loops, instead of a simple strlen function which needs strlen-loops.
It handles all characters.

The strange expression (set^ tmp=!%~2!) is necessary to handle ultra long strings, else it’s not possible to copy them.

More Related Contents:

  1. How to rename file by replacing substring using batch in Windows [closed]
  2. How does the Windows Command Interpreter (CMD.EXE) parse scripts?
  3. What is the reason for “X is not recognized as an internal or external command, operable program or batch file”?
  4. How to run a PowerShell script without displaying a window?
  5. Escape percent in bat file
  6. How to run batch file from network share without “UNC path are not supported” message?
  7. Windows Batch File Looping Through Directories to Process Files?
  8. Secure FTP using Windows batch script
  9. How can two text files be read in parallel by a batch file?
  10. Capture output command CMD
  11. Why does ECHO command print some extra trailing space into the file?
  12. How to create batch file in Windows using “start” with a path and command with spaces
  13. Is there a way to redirect ONLY stderr to stdout (not combine the two) so it can be piped to other programs?
  14. Why does only the first line of this Windows batch file execute but all three lines execute in a command shell?
  15. Batch file to split .csv file
  16. Running another program in Windows bat file and not create child process
  17. How to echo “2” (no quotes) to a file, from a batch script?
  18. Why does this batch variable never change even when set?
  19. echo -e equivalent in Windows?
  20. File is older than 4 minutes in Batch file
  21. How do I get the equivalent of dirname() in a batch file?
  22. Why doesn’t my stderr redirection end after command finishes? And how do I fix it?
  23. How to get windows batch’s parent folder
  24. Windows console %DATE% Math
  25. windows batch file with goto command not working
  26. Batch program to to check if process exists
  27. Foolproof way to check for nonzero (error) return code in windows batch file
  28. Windows batch script to delete everything in a folder except one
  29. ERRORLEVEL vs %ERRORLEVEL% vs exclamation mark ERRORLEVEL exclamation mark
  30. Create a list or an array and print each item in Windows Batch

Leave a Comment