How can two text files be read in parallel by a batch file?

by

The trick is to use STDIN redirection < (see also this site) using undefined handles (3 to 9) for the entire code block for file reading, the command set /P in the block to actually read a line and 0<& to redirect the undefined handles back to STDIN for set /P, thus for the respective line to read.

Here is an example how it works:

Supposing there are the following two text files names.txt…:

Black
Blue
Green
Aqua
Red
Purple
Yellow
White
Grey
Brown

…and values.txt…:

0
1
2
3
4
5
6
7

…and the goal is to combine them line by line to achieve this file, names=values.txt…:

Black=0
Blue=1
Green=2
Aqua=3
Red=4
Purple=5
Yellow=6
White=7

…the following code accomplishes that (see all the explanatory comments, rem):

@echo off
setlocal EnableExtensions EnableDelayedExpansion

rem // Define constants here:
set "FILE1=names.txt"
set "FILE2=values.txt"
set "RET=names=values.txt" & rem // (none to output to console)
if not defined RET set "RET=con"

rem /* Count number of lines of 1st file (2nd file is not checked);
rem    this is necessary to know when to stop reading: */
for /F %%C in ('^< "%FILE1%" find /C /V ""') do set "NUM1=%%C"

rem /* Here input redirection is used, each file gets its individual
rem    (undefined) handle (that is not used by the system) which is later
rem    redirected to handle `0`, `STDIN`, in the parenthesised block;
rem    so the 1st file data stream is redirected to handle `4` and the
rem    2nd file to handle `3`; within the block, as soon as a line is read
rem    by `set /P` from a data stream, the respective handle is redirected
rem    back to `0`, `STDIN`, where `set /P` expects its input data: */
4< "%FILE1%" 3< "%FILE2%" > "%RET%" (
     rem // Loop through the number of lines of the 1st file:
     for /L %%I in (1,1,%NUM1%) do (
         set "LINE1=" & rem /* (clear variable to maintain empty lines;
                        rem     `set /P` does not change variable value
                        rem     in case nothing is entered/redirected) */
         rem // Change handle of 1st file back to `STDIN` and read line:
         0<&4 set /P "LINE1="
         set "LINE2=" & rem // (clear variable to maintain empty lines)
         rem // Change handle of 2nd file back to `STDIN` and read line:
         0<&3 set /P "LINE2="
         rem /* Return combined pair of lines (only if line of 2nd file is
         rem    not empty as `set /P` sets `ErrorLevel` on empty input): */
         if not ErrorLevel 1 echo(!LINE1!=!LINE2!
     )
)

endlocal
exit /B

More Related Contents:

  1. Variables are not behaving as expected
  2. Single line with multiple commands using Windows batch file
  3. Batch file to delete files older than N days
  4. How to have multiple colors in a Windows batch file?
  5. How do I measure execution time of a command on the Windows command line?
  6. Batch file: Find if substring is in string (not in a file)
  7. Windows Batch Variables Won’t Set
  8. ‘Pretty print’ windows %PATH% variable – how to split on ‘;’ in CMD shell
  9. Where is “START” searching for executables?
  10. How to verify if a file exists in a batch file?
  11. Windows command to convert Unix line endings?
  12. windows batch SET inside IF not working
  13. Stop and Start a service via batch or cmd file?
  14. Windows batch script to read an .ini file
  15. How to run a PowerShell script within a Windows batch file
  16. Counting in a FOR loop using Windows Batch script
  17. cmd is somehow writing Chinese text as output
  18. Special Characters in Batch File
  19. Batch to remove duplicate rows from text file
  20. How to count no of lines in text file and store the value into a variable using batch script?
  21. How to test if a path is a file or directory in Windows batch file?
  22. Rename multiple files in cmd
  23. Split string with string as delimiter
  24. How to change Screen buffer size in Windows Command Prompt from batch script
  25. Delete all files and folders in a directory
  26. Windows shell command to get the full path to the current directory?
  27. windows cmd: problems with for /f with a quoted command with quoted parameters
  28. Remove trailing spaces from a file using Windows batch?
  29. Using echo y as an automated response to a pcp hostkey prompt
  30. Batch file to upload .txt to FTP

Leave a Comment