‘Pretty print’ windows %PATH% variable – how to split on ‘;’ in CMD shell

by

The simple way is to use

for %a in ("%path:;=";"%") do @echo %~a

This works for all without ; in the path and without " around a single element
Tested with path=C:\qt\4.6.3\bin;C:\Program Files;C:\documents & Settings

But a “always” solution is a bit complicated
EDIT: Now a working variant 

@echo off
setlocal DisableDelayedExpansion
set "var=foo & bar;baz<>gak;"semi;colons;^&embedded";foo again!;throw (in) some (parentheses);"unmatched ;-)";(too"

set "var=%var:"=""%"
set "var=%var:^=^^%"
set "var=%var:&=^&%"
set "var=%var:|=^|%"
set "var=%var:<=^<%"
set "var=%var:>=^>%"

set "var=%var:;=^;^;%"
rem ** This is the key line, the missing quote is intended
set var=%var:""="%
set "var=%var:"=""%"

set "var=%var:;;="";""%"
set "var=%var:^;^;=;%"
set "var=%var:""="%"
set "var=%var:"=""%"
set "var=%var:"";""=";"%"
set "var=%var:"""="%"

setlocal EnableDelayedExpansion
for %%a in ("!var!") do (
    endlocal
    echo %%~a
    setlocal EnableDelayedExpansion
)

What did I do there?
I tried to solve the main problem: that the semicolons inside of quotes should be ignored, and only the normal semicolons should be replaced with ";"

I used the batch interpreter itself to solve this for me.

  • First I have to make the string safe, escaping all special characters.
  • Then all ; are replaced with ^;^;
  • and then the trick begins with the line
    set var=%var:"=""%" (The missing quote is the key!).
    This expands in a way such that all escaped characters will lose their escape caret:
    var=foo & bar;;baz<>gak;;"semi^;^;colons^;^;^&embedded";;foo again!;;…
    But only outside of the quotes, so now there is a difference between semicolons outside of quotes ;; and inside ^;^;.
    Thats the key.

More Related Contents:

  1. Variables are not behaving as expected
  2. Single line with multiple commands using Windows batch file
  3. Example of delayed expansion in batch file
  4. How do I run two commands in one line in Windows CMD?
  5. Batch command date and time in file name
  6. Windows batch: echo without new line
  7. Where is “START” searching for executables?
  8. How to test if a file is a directory in a batch script?
  9. windows batch SET inside IF not working
  10. How can two text files be read in parallel by a batch file?
  11. Batch files: List all files in a directory with relative paths
  12. How to run a PowerShell script within a Windows batch file
  13. Windows batch script to parse CSV file and output a text file
  14. Using parameters in batch files at Windows command line
  15. “rd” exits with errorlevel set to 0 on error when deletion fails, etc
  16. Convert a small PS script into a long line in a .BATch file
  17. Curl not recognized as an internal or external command, operable program or batch file
  18. What is the easiest way to reset ERRORLEVEL to zero?
  19. Remove unwanted path name from %path% variable via batch
  20. Why is the FOR /f loop in this batch script evaluating a blank line?
  21. How to count no of lines in text file and store the value into a variable using batch script?
  22. How to test if a path is a file or directory in Windows batch file?
  23. How do I minimize the command prompt from my bat file
  24. Path prefixes \??\ and \\?\
  25. What would be the Windows batch equivalent for HTML’s input type=”password”?
  26. Windows console %DATE% Math
  27. Batch program to to check if process exists
  28. How can I source variables from a .bat file into a PowerShell script?
  29. How to expand a CMD shell variable twice (recursively)
  30. Split %date% in a batch file regardless of Regional Settings

Leave a Comment