How to have multiple colors in a Windows batch file?

by

You can do multicolor outputs without any external programs.

@echo off
SETLOCAL EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
  set "DEL=%%a"
)
echo say the name of the colors, don't read

call :ColorText 0a "blue"
call :ColorText 0C "green"
call :ColorText 0b "red"
echo(
call :ColorText 19 "yellow"
call :ColorText 2F "black"
call :ColorText 4e "white"

goto :eof

:ColorText
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1
goto :eof

It uses the color feature of the findstr command.

Findstr can be configured to output line numbers or filenames in a defined color.
So I first create a file with the text as filename, and the content is a single <backspace> character (ASCII 8).
Then I search all non empty lines in the file and in nul, so the filename will be output in the correct color appended with a colon, but the colon is immediatly removed by the <backspace>.

EDIT: One year later … all characters are valid

@echo off
setlocal EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
  set "DEL=%%a"
)

rem Prepare a file "X" with only one dot
<nul > X set /p ".=."

call :color 1a "a"
call :color 1b "b"
call :color 1c "^!<>&| %%%%"*?"
exit /b

:color
set "param=^%~2" !
set "param=!param:"=\"!"
findstr /p /A:%1 "." "!param!\..\X" nul
<nul set /p ".=%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%"
exit /b

This uses the rule for valid path/filenames.
If a \..\ is in the path the prefixed elemet will be removed completly and it’s not necessary that this element contains only valid filename characters.

More Related Contents:

  1. Variables are not behaving as expected
  2. Single line with multiple commands using Windows batch file
  3. Batch file to delete files older than N days
  4. How do I measure execution time of a command on the Windows command line?
  5. Iterate all files in a directory using a ‘for’ loop
  6. How to wait all batch files to finish before exiting?
  7. Windows Batch Variables Won’t Set
  8. ‘Pretty print’ windows %PATH% variable – how to split on ‘;’ in CMD shell
  9. Find out if file is older than 4 hours in Batch file
  10. How to verify if a file exists in a batch file?
  11. Windows command to convert Unix line endings?
  12. Stop and Start a service via batch or cmd file?
  13. How do I echo and send console output to a file in a bat script?
  14. Set a persistent environment variable from cmd.exe
  15. IF… OR IF… in a windows batch file
  16. Copy text from a Windows CMD window to clipboard
  17. How to run a PowerShell script within a Windows batch file
  18. Counting in a FOR loop using Windows Batch script
  19. How to count no of lines in text file and store the value into a variable using batch script?
  20. How to test if a path is a file or directory in Windows batch file?
  21. Rename multiple files in cmd
  22. Split string with string as delimiter
  23. How to change Screen buffer size in Windows Command Prompt from batch script
  24. Delete all files and folders in a directory
  25. Remove trailing spaces from a file using Windows batch?
  26. How to read input from console in a batch file?
  27. Batch goto loses errorlevel
  28. Escape percent signs in given variables
  29. Out of a git console: how do I execute a batch file and then return to git console?
  30. UTF-16 to UTF-8 conversion (for scripting in Windows)

Leave a Comment